數據透視緩存運行時錯誤：VBA 中的類型不匹配

Question

我正在嘗試使用以下代碼創建一個 pivot 表：

Sub pivot()
Windows("DATA.xlsx").Activate
Dim PSheet As Worksheet
Dim DSheet As Worksheet
Dim PCache As PivotCache
Dim PTable As PivotTable
Dim PRange As Range
Dim LastRow As Long
Dim LastCol As Long

'Insert a New Blank Worksheet
Sheets.Add Before:=ActiveSheet
ActiveSheet.Name = "PivotTable"
Application.DisplayAlerts = True
Set PSheet = Worksheets("PivotTable")
Set DSheet = Worksheets("Sheet1")

'Define Data Range
LastRow = DSheet.Cells(Rows.Count, 1).End(xlUp).Row
LastCol = DSheet.Cells(1, Columns.Count).End(xlToLeft).Column
Set PRange = DSheet.Cells(1, 1).Resize(LastRow, LastCol)


Set PCache = ActiveWorkbook.PivotCaches.Create( _
             SourceType:=xlDatabase, _
             SourceData:=PRange)

Set PTable = PCache.CreatePivotTable(TableDestination:=PSheet.Cells(1, 1), TableName:="PivotTable1")

我得到一個錯誤

Set PCache = ActiveWorkbook.PivotCaches.Create( _
                 SourceType:=xlDatabase, _
                 SourceData:=PRange)

它說運行時錯誤 13：類型不匹配錯誤。 有人可以幫忙解決這個問題嗎？

Answer 1

Set PCache = ActiveWorkbook.PivotCaches.Create( _
             SourceType:=xlDatabase, _
             SourceData:=PRange.Address(, , , True))

這解決了問題