如何為連接到 I2C gpio 擴展器的虛擬 mdio-gpio 設備配置 ACPI *.asl

Question

我正在使用 Q7 模塊 (x86) 並嘗試在 Linux 上使用 ACPI SSDT 覆蓋配置我們的外圍設備。 但我與它斗爭。 我想我誤解了 ACPI 的一些核心概念。

問題

CPU -> I2C -> PCA9575 GPIO Expander -> virtual,mdio-gpio -> Ethernet Phy

什么有效

DefinitionBlock ("abc.asl", "SSDT", 2, "test", "HAL", 2)
{
    External (\_SB_.PCI0.D01D, DeviceObj)

    Scope (\_SB.PCI0.D01D)
    {
        Device (ABC0)
        {
            Name (_HID, "PRP0001")                      // must be PRP0001 that linux searches for compatible driver
            Name (_CRS, ResourceTemplate () {
                        I2cSerialBusV2 (
                                0x20,                  // SlaveAddress    : I2C Address
                                ControllerInitiated,   // SlaveMode       : ControllerInitiated
                                100000,                // ConnectionSpeed : max Bus Speed for this device
                                AddressingMode7Bit,    // AddressingMode  : Adress Mode
                                "\\_SB.PCI0.D01D",     // ResourceSource  : I2C host controller
                                0x00,                  // ResourceSourceIndex : must be 0
                                ResourceConsumer,      // ResourceUsage   : must be ResourceConsumer
                                ,                      // DescriptorName  : optional name for integer value which is an offset to a buffer field...
                                Exclusive              // Shared          : Shared or Exclusive
                                ,)                     // VendorData      : optional field                                
            })

            Name (_DSD, Package() {
                    ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
                    Package () {
                            Package (2) { "compatible", "nxp,pca9575"  },
                            Package ()  { "gpio-line-names", Package ()
                                                        {       "LED_Red",
                                                                "",
                                                                "MDC",
                                                                "MDIO",
                                                        }
                                        },
                        },
                    ToUUID("dbb8e3e6-5886-4ba6-8795-1319f52a966b"),
                    Package () {
                        Package () { "led-red",   "LED0" },
                        Package () { "mdc-gpios",  "MDC0" },
                        Package () { "mdio-gpios", "MDIO" },
                    }
            })

            Name (LED0, Package () {
            ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
            Package () {
                Package () {"gpio-hog", 1},
                Package () {"gpios", Package () {0, 1}},
                Package () {"output-low", 1},
              }
            })

... <placeholder for virtual,mdio-gpiocode here> ...

        }
    }
}

它識別 PCA9575 GPIO 擴展器並將其注冊為 Linux 中的 gpiochip。 LED 固定為低且“被占用”。 這部分似乎並不完全錯誤。

什么不起作用

我將此代碼插入占位符

Device (MD00)
        {
            Name (_HID, "PRP0001")                      // must be PRP0001 that linux searches for compatible driver

            Name (_DSD, Package() {
                    ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
                    Package () {
                            Package (2) { "compatible", "virtual,mdio-gpio" },
                            Package () {"gpios", Package () {^MDC0, 2, 0, 
                                                             ^MDIO, 3, 0,}},
                            }
            })
        }

但是，當我嘗試通過 configfs 加載此文件時，我可以在dmesg中看到一條錯誤消息，指出 _CRS 字段中已定義資源的兼容字段丟失。 但我什至沒有定義 _CRS 字段。

我也不確定我的 GPIO 是否定義正確。 我無法使用Package () {"gpios", Package () {0, 1}},命令設置拉模式。

我問自己，GPIO 擴展器端口是否應該再次定義為 MDO 設備中的 GgioIo 結構？

Name (_CRS, ResourceTemplate () {
        GpioIo (Exclusive, PullNone, 0, 0, IoRestrictionNone,
                "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {2}
        GpioIo (Exclusive, PullNone, 0, 0, IoRestrictionNone,
                "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {3}
    })

它似乎也不起作用，我很困惑。 我不確定我是否正確使用了 GPIO PCA9575 驅動程序。 我可以在哪里配置 ACPI 中的拉動偏差？ 驅動程序從of_加載配置，但我不知道在 ACPI 中的何處定義它。 我希望這里有人有想法。

Answer 1

首先讓我們看看設計的主要架構：

+-------------------+
|  HOST             |       +------+
|              MDIO <------>+ MDIO |
|              Intf |       | Phy  |
|                   |       +--^---+
| +------+          |          |       +-----+
| | I²C  |          |          |       | LED |
| | host |          |          |       +--^--+
| +--^---+          |          |          |
|    |              |       +--+---+      |
+-------------------+       | I²C  |      |
     +----------------------> GPIO +------+
                            +------+

從這個示意圖中，我們可以看到設備是如何相互關聯的。 現在讓我們轉向 ACPI 表示。 一開始我們需要定義 I²C GPIO 擴展器。 從meta-acpi項目中的示例中，我們可以找到如何描述 PCA9535。 假設我們找到了 I²C 主機 controller 設備（ \_SB_.PCI0.D01D根據您的帖子）並且您有擴展器而沒有鎖定 IRQ 事件，以下是原始 ASL 摘錄之間的混合以及如何將其與正確配置相匹配司機：

Device (ABC0)
{

    Name (_HID, "PRP0001")
    Name (_DDN, "NXP PCA9575 GPIO expander")

    Name (RBUF, ResourceTemplate()
    {
        I2cSerialBusV2(0x0020, ControllerInitiated, 400000,
            AddressingMode7Bit, "\\_SB.PCI0.D01D",
            0x00, ResourceConsumer, , Exclusive, )
    })

    Name (_DSD, Package () {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () {"compatible", "nxp,pca9575"},
            Package () {"gpio-line-names", Package () {
                "LED_Red",
                "",
                "MDC",
                "MDIO",
            }},
        }
    })

    Method (_CRS, 0, NotSerialized)
    {
        Return (RBUF)
    }

    Method (_STA, 0, NotSerialized)
    {
        Return (0x0F)
    }
}

這段摘錄為我們提供了系統中一個新的 GPIO 芯片，其資源可以被其他人使用。

例如，在您的 Virtual MDIO Phy 案例中（參見_DSD Device Properties Related to GPIO as well）

Device (MD00)
{
    Name (_HID, "PRP0001")

    Name (_CRS, ResourceTemplate () {
        GpioIo (Exclusive, PullDown, 0, 0, IoRestrictionOutputOnly,
            "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {2} // pin 2
        GpioIo (Exclusive, PullDown, 0, 0, IoRestrictionOutputOnly,
            "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {3} // pin 3
    })

    Name (_DSD, Package() {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () { "compatible", "virtual,mdio-gpio" },
            Package () {
                "gpios", Package () {
                    ^MD00, 0, 0, 0, // index 0 in _CRS -> pin 2
                    ^MD00, 1, 0, 0, // index 1 in _CRS -> pin 3
                }
            },
        }
    })
}

現在是時候查看 LED 綁定代碼了。 為澄清起見，當您希望 GPIO提供程序自己使用資源時，就會出現占用。 這很可能不是你的情況。 最好將它與 LED GPIO 驅動程序連接：

Device (LEDS)
{
    Name (_HID, "PRP0001")
    Name (_DDN, "GPIO LEDs device")

    Name (_CRS, ResourceTemplate () {
        GpioIo (
            Exclusive,                  // Not shared
            PullUp,                     // Default off
            0,                          // Debounce timeout
            0,                          // Drive strength
            IoRestrictionOutputOnly,    // Only used as output
            "\\_SB.PCI0.D01D.ABC0",     // GPIO controller
            0)                          // Must be 0
        {
            0,                          // LED_Red
        }
    })

    Name (_DSD, Package () {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () { "compatible", Package() { "gpio-leds" } },
        },
        ToUUID("dbb8e3e6-5886-4ba6-8795-1319f52a966b"),
        Package () {
            Package () { "led-0", "LED0" },
        }
    })

    /*
     * For more information about these bindings see:
     * Documentation/devicetree/bindings/leds/common.yaml,
     * Documentation/devicetree/bindings/leds/leds-gpio.yaml and
     * Documentation/firmware-guide/acpi/gpio-properties.rst.
     */
    Name (LED0, Package () {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () { "label", "red" },
            Package () { "default-state", "on" },
            Package () { "gpios", Package () { ^LEDS, 0, 0, 1 } }, // active low
        }
    })
}

您也可以在 StackOverflow 網站上查看類似的問題（從給定的鏈接開始，並且有對其余部分的引用）。