![](/img/trans.png)
[英]Prolog tries to find other solutions but I don't know why (there is only one)
[英]Prolog tries to find multiple solutions when only one exists
我在https://swish.swi-prolog.org上做了一個基本謂詞ascending/1
來檢查列表是否按升序排列。
ascending([]).
ascending([_]).
ascending([X, Y| T]) :-
X =< Y,
ascending([Y|T]).
如果我查詢?- ascending([1, 2, 4, 6]).
:
如,它試圖找到更多的解決方案。 按Next
、 10
、 100
或1,000
只會返回false
,這本身就是一個謎——同時為真和假? 也許那是因為匿名_
? 我定義的不夠完整嗎? 為什么它不只是返回真實?
大多數 Prolog 系統都實現了第一個參數索引,這樣可以避免創建虛假的選擇點。 假設與第一個參數綁定的調用,在您的代碼的情況下,Prolog 運行時能夠區分第一個子句,其第一個參數是一個原子,和另外兩個子句,其第一個參數是列表. 但不能(通常)區分第二個和第三個子句,並避免為第一個參數是列表的目標嘗試兩者。 這導致創建選擇點。 因此,您得到的結果:
?- ascending([1, 2, 4, 6]).
true ;
false.
但我們可以改進您的解決方案。 例如:
ascending([]).
ascending([Head| Tail]) :-
ascending(Tail, Head).
ascending([], _).
ascending([Head| Tail], Previous) :-
Previous =< Head,
ascending(Tail, Head).
我們現在將得到:
?- ascending([1, 2, 4, 6]).
true.
?- ascending([1, 2, 4, 6, 1]).
false.
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.