回復所有附件

Question

我有這個代碼到 vba outlook 宏來回復所有。

Sub my_test()

Dim objItem As Object

Dim mail As MailItem
Dim replyall As MailItem

Dim templateItem As MailItem

For Each objItem In ActiveExplorer.Selection

    If objItem.Class = olMail Then
    
        Set mail = objItem
        Set replyall = mail.replyall
                
        Set templateItem = CreateItemFromTemplate("C:\template.oft")
        
        With replyall
            .HTMLBody = templateItem.HTMLBody & .HTMLBody
            .Display
        End With
        
    End If
    
Next

End Sub

我正在嘗試添加一個功能，以便當原始 email 帶來附件（docx，pdf）時，當我使用此宏全部回復時，它也將使用原始附件並將其作為附件放置在所有 email 回復中。 我怎樣才能做到這一點？

Answer 1

轉發然后用ReplyAll 中出現的內容填充.To 。

Option Explicit

Sub my_test()

Dim objItem As Object

Dim mail As MailItem
Dim forwardMail As MailItem

Dim templateItem As MailItem

For Each objItem In ActiveExplorer.Selection

    If objItem.Class = olMail Then
    
        Set mail = objItem
        Set forwardMail = mail.Forward
        
        Set templateItem = CreateItemFromTemplate("C:\template.oft")
        
        With forwardMail
            .HTMLBody = templateItem.HTMLBody & .HTMLBody
            .To = mail.replyall.To
            .Display
        End With
        
    End If
    
Next

End Sub