XPath/XSL：通過單個 for-each 循環生成一個干凈的表
[英]XPath/XSL: produce a clean table through a single for-each loop
問題描述
可能是一個非常簡單的問題，但我想通過使用 Xpath 在我的 XSL 文件中使用單個 for-each 循環來生成一個干凈的表。 我已經走了很長一段路，這導致了您可以在下面看到的結果文件和圖像。
XSL 文件
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<html>
<body>
<h2>Provincies</h2>
<table border="1">
<tr>
<th bgcolor="#9acd32" style="text-align:left">Provincie</th>
<th bgcolor="#9acd32" style="text-align:left">Gemeente</th>
<th bgcolor="#9acd32" style="text-align:left">Stad</th>
<th bgcolor="#9acd32" style="text-align:left">Aantal bedrijven</th>
</tr>
<xsl:for-each select="bedrijven/provincie/gemeente/stad">
<xsl:variable name="provincie" select="../../@naam"/>
<xsl:variable name="gemeente" select="../@naam"/>
<xsl:variable name="stad" select="@naam"/>
<tr>
<xsl:choose>
<xsl:when test="preceding::*/text() != $provincie"><td></td></xsl:when>
<xsl:otherwise><td><xsl:value-of select="$provincie"/></td></xsl:otherwise>
</xsl:choose>
<xsl:choose>
<xsl:when test="preceding-sibling::*/text() != $gemeente"><td></td></xsl:when>
<xsl:otherwise><td><xsl:value-of select="$gemeente"/></td></xsl:otherwise>
</xsl:choose>
<td><xsl:value-of select="$stad"/></td>
<td><xsl:value-of select="count(child::bedrijf)"/></td>
</tr>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>
但是，問題在於它只打印第一個省份而不是其他省份。 我只希望每個省都印一次，不重復。 我整天都在嘗試這樣做，並且到處搜索，但我似乎找不到答案。 所以我希望這里有人可以幫助我。 下面是我的 XML 文件。
XML結構示例
<bedrijven
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:noNamespaceSchemaLocation="file:///C:\Users\Boro\Documents\XML opdrachten\XML Opdrachten\Opdracht 1\db\test.xsd">
<provincie naam="Drenthe">
<gemeente naam="aa en Hunze">
<stad naam="anloo">
<bedrijf>
<naam>v.o.f. Anloo</naam>
<postcode>9468CG</postcode>
</bedrijf>
</stad>
<stad naam="gasselternijveen">
<bedrijf>
<naam>podiumdelen.nl</naam>
<postcode>9514BV</postcode>
</bedrijf>
</stad>
</gemeente>
</provincie>
<provincie naam="Flevoland">
<gemeente naam="almere">
<stad naam="almere">
<bedrijf>
<naam>mood media</naam>
<postcode>1322CE</postcode>
</bedrijf>
<bedrijf>
<naam>dutch Meat Service</naam>
<postcode>1311XC</postcode>
</bedrijf>
<bedrijf>
<naam>jossafety</naam>
<postcode>1338XX</postcode>
</bedrijf>
</stad>
</gemeente>
</provincie>
</bedrijven>
2 個解決方案
解決方案1
1 2021-04-14 20:13:56
我用這段代碼得到了正確的 output ：
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:template match="bedrijven">
<html>
<body>
<h2>Provincies</h2>
<table border="1">
<tr>
<th bgcolor="#9acd32" style="text-align:left">Provincie</th>
<th bgcolor="#9acd32" style="text-align:left">Gemeente</th>
<th bgcolor="#9acd32" style="text-align:left">Stad</th>
<th bgcolor="#9acd32" style="text-align:left">Aantal bedrijven</th>
</tr>
<xsl:for-each select="provincie">
<xsl:variable name="provincie" select="@naam"/>
<xsl:for-each select="gemeente">
<xsl:variable name="gemeente" select="@naam"/>
<xsl:for-each select="stad">
<xsl:variable name="stad" select="@naam"/>
<tr>
<td>
<xsl:if
test="count(preceding::stad[
ancestor::provincie/@naam = $provincie
]) = 0">
<xsl:value-of select="$provincie"/>
</xsl:if>
</td>
<td>
<xsl:if
test="count(preceding::stad[
ancestor::gemeente/@naam = $gemeente
]) = 0">
<xsl:value-of select="$gemeente"/>
</xsl:if>
</td>
<td>
<xsl:value-of select="$stad"/>
</td>
<td>
<xsl:value-of select="count(child::bedrijf)"/>
</td>
</tr>
</xsl:for-each>
</xsl:for-each>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>
我使用三個級別的<xsl:for-each>來避免在每次迭代中重新計算$provincie和$gemeente 。
我使用一個簡單的測試來查看字段provincie或gemeente是否對應於provincie或gemeente內部的第一個stad 。 如果它是第一次出現（這意味着前面的計數為零），我打印它的值。
Martin Ronnen 在上面的評論中建議在輸出結果時利用 HTML 屬性行rowspan 。 如果你喜歡這個想法，你可以這樣修改代碼：
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:template match="bedrijven">
<html>
<body>
<h2>Provincies</h2>
<table border="1">
<tr>
<th bgcolor="#9acd32" style="text-align:left">Provincie</th>
<th bgcolor="#9acd32" style="text-align:left">Gemeente</th>
<th bgcolor="#9acd32" style="text-align:left">Stad</th>
<th bgcolor="#9acd32" style="text-align:left">Aantal bedrijven</th>
</tr>
<xsl:for-each select="provincie">
<xsl:variable name="provincie" select="@naam"/>
<xsl:variable name="steden-per-provincie"
select="count(gemeente/stad)"/>
<xsl:for-each select="gemeente">
<xsl:variable name="gemeente" select="@naam"/>
<xsl:variable name="steden-per-gemeente" select="count(stad)"/>
<xsl:for-each select="stad">
<xsl:variable name="stad" select="@naam"/>
<tr>
<xsl:if
test="count(preceding::stad[
ancestor::provincie/@naam = $provincie
]) = 0">
<td rowspan="{$steden-per-provincie}">
<xsl:value-of select="$provincie"/>
</td>
</xsl:if>
<xsl:if
test="count(preceding::stad[
ancestor::gemeente/@naam = $gemeente
]) = 0">
<td rowspan="{$steden-per-gemeente}">
<xsl:value-of select="$gemeente"/>
</td>
</xsl:if>
<td>
<xsl:value-of select="$stad"/>
</td>
<td style="text-align:right">
<xsl:value-of select="count(child::bedrijf)"/>
</td>
</tr>
</xsl:for-each>
</xsl:for-each>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>
這是使用rowspan屬性的結果的屏幕截圖：
如果你真的需要一個for-each循環，試試這個，但它會不太理想：
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:template match="bedrijven">
<html>
<body>
<h2>Provincies</h2>
<table border="1">
<tr>
<th bgcolor="#9acd32" style="text-align:left">Provincie</th>
<th bgcolor="#9acd32" style="text-align:left">Gemeente</th>
<th bgcolor="#9acd32" style="text-align:left">Stad</th>
<th bgcolor="#9acd32" style="text-align:left">Aantal bedrijven</th>
</tr>
<xsl:for-each select="//stad">
<xsl:variable name="provincie" select="ancestor::provincie/@naam"/>
<xsl:variable name="gemeente" select="ancestor::gemeente/@naam"/>
<xsl:variable name="stad" select="@naam"/>
<tr>
<xsl:if
test="count(preceding::stad[
ancestor::provincie/@naam = $provincie
]) = 0">
<td rowspan="{count(following::stad[
ancestor::provincie/@naam = $provincie
]) + 1}">
<xsl:value-of select="$provincie"/>
</td>
</xsl:if>
<xsl:if
test="count(preceding::stad[
ancestor::gemeente/@naam = $gemeente
]) = 0">
<td rowspan="{count(following::stad[
ancestor::gemeente/@naam = $gemeente
]) + 1}">
<xsl:value-of select="$gemeente"/>
</td>
</xsl:if>
<td>
<xsl:value-of select="$stad"/>
</td>
<td style="text-align:right">
<xsl:value-of select="count(child::bedrijf)"/>
</td>
</tr>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>
最后，如果您想使用xsl:number功能，這里有一個可能更易於閱讀的代碼版本：
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:template match="bedrijven">
<html>
<body>
<h2>Provincies</h2>
<table border="1">
<tr>
<th bgcolor="#9acd32" style="text-align:left">Provincie</th>
<th bgcolor="#9acd32" style="text-align:left">Gemeente</th>
<th bgcolor="#9acd32" style="text-align:left">Stad</th>
<th bgcolor="#9acd32" style="text-align:left">Aantal bedrijven</th>
</tr>
<xsl:for-each select="//stad">
<xsl:variable name="provincie" select="ancestor::provincie/@naam"/>
<xsl:variable name="gemeente" select="ancestor::gemeente/@naam"/>
<xsl:variable name="stad" select="@naam"/>
<xsl:variable name="gemeente-nr">
<xsl:number count="gemeente" from="provincie"/>
</xsl:variable>
<xsl:variable name="stad-nr">
<xsl:number count="stad" from="gemeente"/>
</xsl:variable>
<tr>
<xsl:if test="($gemeente-nr = 1) and ($stad-nr = 1)">
<td rowspan="{count(ancestor::provincie//stad)}">
<xsl:value-of select="$provincie"/>
</td>
</xsl:if>
<xsl:if test="$stad-nr = 1">
<td rowspan="{count(ancestor::gemeente//stad)}">
<xsl:value-of select="$gemeente"/>
</td>
</xsl:if>
<td><xsl:value-of select="$stad"/></td>
<td style="text-align:right">
<xsl:value-of select="count(child::bedrijf)"/>
</td>
</tr>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>
解決方案2
0 已采納 2021-04-15 11:09:27
您可以使用xsl:number ：
<xsl:variable name="gemeente-pos">
<xsl:number level="any" from="provincie"/>
</xsl:variable>
<xsl:variable name="stad-pos">
<xsl:number/>
</xsl:variable>
<tr>
<xsl:choose>
<xsl:when test="$gemeente-pos != 1"><td></td></xsl:when>
<xsl:otherwise><td><xsl:value-of select="$provincie"/></td></xsl:otherwise>
</xsl:choose>
<xsl:choose>
<xsl:when test="$stad-pos != 1"><td></td></xsl:when>
<xsl:otherwise><td><xsl:value-of select="$gemeente"/></td></xsl:otherwise>
</xsl:choose>
<td><xsl:value-of select="$stad"/></td>
<td><xsl:value-of select="count(child::bedrijf)"/></td>
</tr>
使用XPath選擇xsl：for-each常規序列之外的節點
[英]Using XPath to select nodes outside of the normal sequence of xsl:for-each
XSL使用rowspan = for-each循環中的迭代次數創建html頭
[英]XSL create html header with rowspan = number of iterations in for-each loop
如何在具有4列的一個表中顯示數據。注意：使用了兩個xsl：for-each語句
[英]How to display data in one table with 4 columns.Note: Two xsl:for-each statements are used
XSL 風格：使用<xsl:for-each select>或者<xsl:template match>或 XSLT 中的其他解決方案？</xsl:template></xsl:for-each>
[英]XSL style: using <xsl:for-each select> or <xsl:template match> or other solutions in XSLT?
聲明:本站的技術帖子網頁，遵循CC BY-SA 4.0協議，如果您需要轉載，請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.
相關問題
XSL中單選按鈕的每個循環
使用XPath選擇xsl：for-each常規序列之外的節點
XSL-for-each不起作用
XSL使用rowspan = for-each循環中的迭代次數創建html頭
XML 轉表<for-each></for-each>
如何為xsl for-each語句添加條件
在相同的XML子代上使用XSL for-each
如何在具有4列的一個表中顯示數據。注意：使用了兩個xsl：for-each語句
運用 <xsl: param> 上 <xsl: for-each> 不起作用
XSL 風格：使用<xsl:for-each select>或者<xsl:template match>或 XSLT 中的其他解決方案？</xsl:template></xsl:for-each>
相關標簽