Pincescript 獲取高值和低值的平均值

Question

我從交易視圖中獲得了以下代碼。 如何從標記中添加另一條高點和低點的平均線。

示例：以下代碼將圖表標記為 5 分鍾時間范圍內 30 分鍾蠟燭的最高點和最低點。 所以，我想添加另一條高點和低點的平均線。

study(title="ORB-30Min", shorttitle="ORB30", overlay=true)
up30on = input(true, title="35 Minute Opening Range High")
down30on = input(true, title="35 Minute Opening Range Low")

is_newbar(res) => change(time(res)) != 0 

adopt(r, s) => security(tickerid, r, s) 

high_range = valuewhen(is_newbar('D'),high,0)
low_range = valuewhen(is_newbar('D'),low,0)

high_rangeL = valuewhen(is_newbar('D'),high,0) 
low_rangeL = valuewhen(is_newbar('D'),low,0) 

//averaged = (high_rangeL + low_rangeL)/2

up30 = plot(up30on ? adopt('30', high_rangeL): na, color = #333fff, style=line, linewidth=1) 
down30 = plot(down30on ? adopt('30', low_rangeL): na, color = #333fff, style=line, linewidth=1) 

//ave = plot(down30on ? adopt('30', low_rangeL): na, color = #e97d53, style=line, linewidth=1) 


trans30 = up30on ?  97 : 100
fill(up30, down30, color = white, transp=trans30)

Answer 1

//@version=4
study(title="ORB-30Min", shorttitle="ORB30", overlay=true)

up30on = input(true, title="35 Minute Opening Range High")
down30on = input(true, title="35 Minute Opening Range Low")
avg30on = input(true, title="35 Minute Opening Range Average")

is_newbar(res) => change(time(res)) != 0 

adopt(r, s) => security(syminfo.tickerid, r, s) 

high_range = valuewhen(is_newbar('D'),high,0)
low_range = valuewhen(is_newbar('D'),low,0)

high_rangeL = valuewhen(is_newbar('D'),high,0) 
low_rangeL = valuewhen(is_newbar('D'),low,0) 


up30 = plot(up30on ? adopt('30', high_rangeL): na, color = #333fff, style=plot.style_stepline, linewidth=1) 
down30 = plot(down30on ? adopt('30', low_rangeL): na, color = #333fff, style=plot.style_stepline, linewidth=1) 

avg30 = plot(avg30on ? adopt('30', avg(high_rangeL,low_rangeL)): na, color = #e97d53, style=plot.style_stepline, linewidth=1) 

color30 = up30on ?  color.new(color.white,97) : color.new(color.white,100)
fill(up30, down30, color = color30)