Terraform for_each 迭代超過 object

Question

我對 Terraform 比較陌生，我希望簡化一些我需要使用 for_each 創建的私有 r53 區域。

我有以下本地文件，我想用它來創建私有區域和在這些區域中關聯的 A 記錄：

locals {
  private_zones = [
    {
      name = "foo.com"
      txt = [
      "This is the txt record for foo.com"]
      ttl = 300
      records = {
        "host1" = "192.168.0.1",
        "host2" = "192.168.0.2"
      }
    },
    {
      name = "bar.com"
      txt = [
      "This is the txt record for bar.com"]
      ttl = 300
      records = {
        "host1" = "192.168.0.3",
        "host2" = "192.168.0.4"
      }
    }
  ]
}

我找到了一些代碼，可以讓我遍歷本地以創建區域

resource "aws_route53_zone" "zone" {
  for_each = { for name in local.private_zones : name.name => name }
  name     = each.value.name

  vpc {
    vpc_id = <vpc_id>
  }
}

但我不知道如何使用每個本地的記錄列表在各自的區域中迭代和創建 A 記錄。

Answer 1

您將使用aws_route53_record和扁平化的private_zones ：

locals {
    private_zones_flat = merge([
        for zone in local.private_zones: {
            for host, ip in zone.records:
                "${zone.name}-${host}" => {
                    zone_name = zone.name
                    host = host
                    ip = ip
                }
        }
    ]...)
}

resource "aws_route53_record" "host" {
  for_each = local.private_zones_flat
  zone_id = aws_route53_zone.zone[each.value.zone_name].zone_id
  name    = each.value.host
  type    = "A"
  ttl     = "300"
  records = [each.value.ip]
}