查找數字總和最高的行名

Question

在下面的電子表格中，我試圖找到不同時間總銷售額最高的商品。

我想輕松提取最高和最低銷售項目名稱以及它們相應的總銷售額。 我需要能夠在不創建幫助列的情況下執行此操作，因為我無法編輯表格。

我知道可能有一種簡單的方法可以做到這一點，但對於我的生活，我無法弄清楚！

鏈接到工作表

Answer 1

B12：

=INDEX(SORT(SPLIT(FLATTEN(B2:G10&"×"&A2:A10&"×"&B1:G1), "×"), 1, 0), 1, 2)

B13：

=INDEX(SORT(SPLIT(FLATTEN(B2:G10&"×"&A2:A10&"×"&B1:G1), "×"), 1, 0), 1, 1)

B14：

=INDEX(SORT(SPLIT(FLATTEN(B2:G10&"×"&A2:A10&"×"&B1:G1), "×"), 1, 1), 1, 2)

B15：

=INDEX(SORT(SPLIT(FLATTEN(B2:G10&"×"&A2:A10&"×"&B1:G1), "×"), 1, 1), 1, 1)

Answer 2

** 編輯：使用 player0 的整體最小值和最大值。

檢查此演示表

要按時隙獲得最高或最低（將其放在 I5 中），

=ARRAYFORMULA(
  IFERROR(
   VLOOKUP(
    TRANSPOSE(B1:G1),
    SORT(
     SPLIT(
      FLATTEN(B1:G1&"|"&A2:A&"|"&B2:G),
      "|"),
     3,FALSE),
    {1,2,3},FALSE)))

然后將每個時隙的最低值與之對齊，將其放入 M5

=ARRAYFORMULA(
  IF(ISBLANK(I5:I),,
   IFERROR(
    VLOOKUP(
     I5:I,
     SORT(
      SPLIT(
       FLATTEN(B1:G1&"|"&A2:A&"|"&B2:G),
       "|"),
      3,FALSE),
     {2,3},FALSE))))

如果您還想要每日高點和低點的條件格式，請使用 B2:G 范圍

=AND(LEN(B2),MIN($B2:$G2)=B2)

如果您真的想將這些公式放在表格下方，請更改

FLATTEN(B1:G1&"|"&A2:A&"|"&B2:G),

至

FLATTEN(B1:G1&"|"&A2:A10&"|"&B2:G10),