[英]How to convert SVG file to PNG file with transparency using Delphi
我想以編程方式將 SVG 文件轉換為 PNG 文件。
我使用 Delphi 10.3.3 和Skia4Delphi ,但這個代碼片段不尊重透明度。 它創建黑色背景。
var
LBitmap: TBitmap;
MyPng: TPNGImage;
begin
if opendialog1.Execute then
begin
LBitmap := TBitmap.Create;
try
LBitmap.SetSize(1000,1000);
LBitmap.Transparent := True;
LBitmap.SkiaDraw(
procedure (const ACanvas: ISKCanvas)
var
LSvgBrush: TSkSvgBrush;
begin
LSvgBrush := TSkSvgBrush.Create;
try
LSvgBrush.Source := TFile.ReadAllText(opendialog1.FileName);
LSvgBrush.Render(ACanvas, RectF(0, 0, LBitmap.Width, LBitmap.Height), 1);
finally
LSvgBrush.Free;
end;
end);
if savedialog1.Execute then
begin
MyPng := TPngImage.Create;
try
MyPng.Assign(LBitmap);
MyPng.SaveToFile(savedialog1.FileName);
finally
MyPng.Free;
end;
end;
finally
LBitmap.Free;
end;
end;
end;
您的問題是在 SkiaDraw 之后,將 bitmap 保存為 png 格式。 這可以非常簡單地完成,無需使用 TPNGImage:
if savedialog1.Execute then
LBitmap.ToSkImage.EncodeToFile(savedialog1.FileName);
但是,在當前版本(3.4.1)中存在與 Bitmap.ToSkImage: https://github.com/skia4delphi/skia4delphi/issues/150相關的問題
另一種解決方案是使用 TPNGImage,但方式不同:
function CreatePNGFromTransparentBitmap(const ABitmap: TBitmap): TPNGImage;
type
TRGB = packed record
B, G, R: Byte;
end;
TRGBAArray = array[0..$effffff] of packed record
B, G, R, A: Byte;
end;
var
X, Y: Integer;
BmpRGBA: ^TRGBAArray;
PngRGB: ^TRGB;
begin
Result := TPNGImage.CreateBlank(COLOR_RGBALPHA, 8, ABitmap.Width , ABitmap.Height);
try
Result.CreateAlpha;
Result.Canvas.CopyMode := cmSrcCopy;
Result.Canvas.Draw(0, 0, ABitmap);
for Y := 0 to Pred(ABitmap.Height) do
begin
BmpRGBA := ABitmap.ScanLine[Y];
PngRGB := Result.ScanLine[Y];
for X := 0 to Pred(ABitmap.Width) do
begin
Result.AlphaScanline[Y][X] := BmpRGBA[X].A;
if ABitmap.AlphaFormat in [afDefined, afPremultiplied] then
begin
if BmpRGBA[X].A <> 0 then
begin
PngRGB^.B := Round(BmpRGBA[X].B / BmpRGBA[X].A * 255);
PngRGB^.R := Round(BmpRGBA[X].R / BmpRGBA[X].A * 255);
PngRGB^.G := Round(BmpRGBA[X].G / BmpRGBA[X].A * 255);
end
else
begin
PngRGB^.B := Round(BmpRGBA[X].B * 255);
PngRGB^.R := Round(BmpRGBA[X].R * 255);
PngRGB^.G := Round(BmpRGBA[X].G * 255);
end;
end;
Inc(PngRGB);
end;
end;
except
Result.Free;
raise;
end;
end;
procedure TForm1.FormCreate(Sender: TObject);
var
LBitmap: TBitmap;
MyPng: TPNGImage;
begin
if opendialog1.Execute then
begin
LBitmap := TBitmap.Create;
try
LBitmap.SetSize(1000, 1000);
LBitmap.SkiaDraw(
procedure (const ACanvas: ISKCanvas)
var
LSvgBrush: TSkSvgBrush;
begin
LSvgBrush := TSkSvgBrush.Create;
try
LSvgBrush.Source := TFile.ReadAllText(opendialog1.FileName);
LSvgBrush.Render(ACanvas, RectF(0, 0, LBitmap.Width, LBitmap.Height), 1);
finally
LSvgBrush.Free;
end;
end);
if savedialog1.Execute then
begin
MyPng := CreatePNGFromTransparentBitmap(LBitmap);
try
MyPng.SaveToFile(savedialog1.FileName);
finally
MyPng.Free;
end;
end;
finally
LBitmap.Free;
end;
end;
end;
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.