如何使用 XSLT 編輯 XML 文件中的元素？

Question

我在這里有一個 XML 文件：

<?xml version="1.0" encoding="utf-16"?>
<class>
    <student>
        <name>Ben</name>
        <age>1</age>
        <ages>4</ages>
        <entryprofile></entryprofile>
        <node>1</node>
    </student>
    <student>
        <name>Steve</name>
        <age>2</age>
        <ages>3</ages>
        <entryprofile></entryprofile>
        <node>1</node>
    </student>
</class>

我正在嘗試提升entryprofile元素，使其成為student的子元素，而不是student的屬性——我希望它包含node 。 為了做到這一點，我嘗試應用以下 XSL：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="student">
  <xsl:copy-of select="name"/>
  <new-level>
     <xsl:copy-of select="entryprofile"/>
  </new-level>
</xsl:template>
</xsl:stylesheet>

這似乎並沒有做太多除了這個：

<?xml version="1.0" encoding="utf-16"?>
    <name>Ben</name><new-level><entryprofile>g</entryprofile></new-level>
    <name>Steve</name><new-level><entryprofile>g</entryprofile></new-level>

但我正在尋找的是：

<?xml version="1.0" encoding="utf-16"?>
<class>
    <student>
        <name>Ben</name>
        <age>1</age>
        <ages>4</ages>
        <entryprofile>
          <node>1</node>
        </entryprofile>
    </student>
    <student>
        <name>Steve</name>
        <age>2</age>
        <ages>3</ages>
        <entryprofile>
          <node>1</node>
        </entryprofile>
    </student>
</class>

您可以在那里看到，由於node成為 entryprofile 的孩子，因此兩個entryprofile的entryprofile都已成為孩子。

有誰知道我哪里出錯了，我能做些什么來達到我想要的結果？ 非常感謝。

Answer 1

試試這個 XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="entryprofile">
        <xsl:copy>
            <xsl:copy-of select="../node"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="node"/>
</xsl:stylesheet>

Answer 2

以下是兩種以略微不同的方式完成相同任務的替代方案：

這是您嘗試做的正確版本：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="student">
    <xsl:copy>
        <xsl:copy-of select="name | age | ages | profile"/>
        <entryprofile>
            <xsl:copy-of select="node"/>
        </entryprofile>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

這是上述版本的較短版本：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/class">
    <xsl:copy>
        <xsl:for-each select="student">
            <xsl:copy>
                <xsl:copy-of select="name | age | ages | profile"/>
                <entryprofile>
                    <xsl:copy-of select="node"/>
                </entryprofile>
            </xsl:copy>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>