Dataweave 2.0 映射轉換

Question

對於 POST 方法，我輸入了以下有效負載：

{
  "order": {
    "Column_X": "X",
    "Column_Y": "Y",
    "Column_Z": "Z",
    "Column_W" : {
      "div_1": "some text",
      "div_2": true,
      "div_3": 2
    }
  },
  "mapper": {
    "A": "<order.Column_X>",
    "B": "<order.Column_Z>",
    "C": "Fields or text not mapped to order",
    "C1": "status",
    "D": {
      "D1": "<order.Column_W.div_1>",
      "D2": "<order.Column_W.div_2>",
      "D3": "<order.Column_W.div_3>",
      "D4": "<order.Column_W.div_4>"
    }
  }
}

這是預期的 output 映射，上面的順序為 object：

{
   "A":"X",
   "B":"Z",
   "C":"Fields or text not mapped to order",
   "C1":"status",
   "D":{
      "D1":"some text",
      "D2":true,
      "D3":2,
      "D4":null
   }
}

我將如何解決這個問題？

Answer 1

我希望這就是你要找的。

%dw 2.0
output application/json
---
{
    A: payload.order.Column_X,
    B: payload.order.Column_Z,
    C: payload.mapper.C,
    C: payload.mapper.C1,
    D: {
        D1: payload.order.Column_W.div_1,
        D2: payload.order.Column_W.div_2,
        D3: payload.order.Column_W.div_3,
        D4: payload.order.Column_W.div_4
    }
}

Output:
{
  "A": "X",
  "B": "Z",
  "C": "Fields or text not mapped to order",
  "C": "status",
  "D": {
    "D1": "some text",
    "D2": true,
    "D3": 2,
    "D4": null
  }
}

Answer 2

這是有點粗略的方法，但希望它能給你一個想法來查詢“訂單” object 有點動態。

%dw 2.0
output application/json
fun returnFromOrder(val : Array) = {
  a:  if (sizeOf(val) ==2) payload."$(val[0])"."$(val[1])"  else payload."$(val[0])"."$(val[1])"."$(val[2])"
}

---
{
    A: returnFromOrder(( payload.mapper.A replace "<" with "" replace ">" with "" splitBy ".")).a,
    B: returnFromOrder(( payload.mapper.B replace "<" with "" replace ">" with "" splitBy ".")).a,
    C: if (returnFromOrder(( payload.mapper.C replace "<" with "" replace ">" with "" splitBy ".")).a == null) payload.mapper.C else "",
    C1: if (returnFromOrder(( payload.mapper.C1 replace "<" with "" replace ">" with "" splitBy ".")).a == null) payload.mapper.C1 else "",
    D: {
        "D1" : returnFromOrder(( payload.mapper.D.D1 replace "<" with "" replace ">" with "" splitBy ".")).a,
        "D2" : returnFromOrder(( payload.mapper.D.D2 replace "<" with "" replace ">" with "" splitBy ".")).a,
        "D3" : returnFromOrder(( payload.mapper.D.D3 replace "<" with "" replace ">" with "" splitBy ".")).a,
        "D4" : returnFromOrder(( payload.mapper.D.D4 replace "<" with "" replace ">" with "" splitBy ".")).a
    }

}

Answer 3

要使其完全動態化，您需要兩件事。

1. 可以從動態路徑中獲取值的 function
2. 使用遞歸來構建有效負載，因為您的映射器本身可以包含更多的映射器對象。

%dw 2.0
output application/json

fun isPath(value) = (value is String) and (value matches "<.+>")

fun getFromPath(json, pathString) = 
    pathString splitBy '.'
        reduce ((path, valueAtPath = json) -> valueAtPath[path])

fun buildUsingMapper(mapper, mappingValues) = 
mapper mapObject ((value, key) -> {
    (key): if(isPath(value)) mappingValues getFromPath value[1 to -2] // eliminate the first "<" and the ending ">". 
            else if(value is Object) buildUsingMapper(value, mappingValues)
            else value
})
---
buildUsingMapper(payload.mapper, payload - "mapper") // you can also pass the full payload instead of payload - "mapper". I did it here to show that the second parameter does not necessarily need the mapper object within.

我假設沒有 arrays 在mapper中有這些動態路徑，或者動態路徑將包括動態訪問數組元素。