使用emacs，如何交換2個窗口的位置

Question

我在Emacs打開了2個窗口，我想換掉他們的位置。

即考慮在源文件上面有一個REPL，我想交換它們的位置，以便REPL低於源文件。

我也想保留窗戶的大小

Answer 1

我無恥地從Steve Yegge的.emacs那里偷走了這個

(defun swap-windows ()
  "If you have 2 windows, it swaps them." 
  (interactive)
  (cond ((not (= (count-windows) 2)) (message "You need exactly 2 windows to do this."))
        (t
         (let* ((w1 (first (window-list)))
                (w2 (second (window-list)))
                (b1 (window-buffer w1))
                (b2 (window-buffer w2))
                (s1 (window-start w1))
                (s2 (window-start w2)))
           (set-window-buffer w1 b2)
           (set-window-buffer w2 b1)
           (set-window-start w1 s2)
           (set-window-start w2 s1)))))

在Gentoo上測試Emacs 23.1.1。 這確實保留了窗口大小。

我也發現這個更干凈一點。

(defun transpose-windows ()
  (interactive)
  (let ((this-buffer (window-buffer (selected-window)))
        (other-buffer (prog2
                          (other-window +1)
                          (window-buffer (selected-window))
                        (other-window -1))))
    (switch-to-buffer other-buffer)
    (switch-to-buffer-other-window this-buffer)
    (other-window -1)))

還在Emacs 23.1.1上進行了測試

Answer 2

以下版本適用於任意數量的窗口。 當有兩個以上的窗口時，重復調用將使所選緩沖區連續出現在每個窗口中。

(defun swap-buffer ()
  (interactive)
  (cond ((one-window-p) (display-buffer (other-buffer)))
        ((let* ((buffer-a (current-buffer))
                (window-b (cadr (window-list)))
                (buffer-b (window-buffer window-b)))
           (set-window-buffer window-b buffer-a)
           (switch-to-buffer buffer-b)
           (other-window 1)))))

Answer 3

我發現TransposeFrame庫很有用。 根據這個問題，我主要使用它來交換兩個窗口; 但它提供了比這更通用的功能。

點擊鏈接查看各種轉換的ascii圖表。

Answer 4

見http://www.emacswiki.org/cgi-bin/wiki/buffer-move.el 。 你可以通過elpa安裝它