腳本從Windows驅動器中提取信息

Question

我需要一個腳本，該腳本可以從Windows操作系統（Server 2003）上的任何驅動器中運行和提取信息，列出包含以下字段的所有文件和文件夾：

• 完整的文件路徑（例如C：\\ Documents and Settings \\ user \\ My Documents \\ testPage.doc）
• 文件類型（例如Word文檔，電子表格，數據庫等）
• 尺寸
• 創建時
• 上次修改時間
• 上次訪問時間

任何幫助表示贊賞。

謝謝

Answer 1

試試這個vbscript

Set objFS=CreateObject("Scripting.FileSystemObject")
Set objArgs = WScript.Arguments
strFolder = objArgs(0)
Set objFolder = objFS.GetFolder(strFolder)
Go (objFolder)
Sub Go(objDIR)
  If objDIR <> "\System Volume Information" Then
    For Each eFolder in objDIR.SubFolders
        Go eFolder
    Next   
  End If
    For Each strFile In objDIR.Files
        WScript.Echo "Full Path: " & strFile.Path
        WScript.Echo "File Size(bytes): " & strFile.Size
        WScript.Echo "File Date modified: " & strFile.DateLastModified
        WScript.Echo "File Date Created: " &  strFile.DateCreated
        WScript.Echo "File Date accessed: " & strFile.DateLastAccessed

    Next 
End Sub 

在命令行上

c:\test> cscript //nologo myscript.vbs c:\

Answer 2

要將結果保存到csv文件，請按以下方式修改ghostdog74的代碼。

Set objFS=CreateObject("Scripting.FileSystemObject")
WScript.Echo Chr(34) & "Full Path" &_
 Chr(34) & ","  & Chr(34) & "File Size" &_
 Chr(34) & ","  & Chr(34) & "File Date modified" &_
 Chr(34) & "," & Chr(34) & "File Date Created" &_
 Chr(34) & "," & Chr(34) & "File Date Accessed" & Chr(34)
Set objArgs = WScript.Arguments
strFolder = objArgs(0)
Set objFolder = objFS.GetFolder(strFolder)
Go (objFolder)
Sub Go(objDIR)
  If objDIR <> "\System Volume Information" Then
    For Each eFolder in objDIR.SubFolders
        Go eFolder
    Next   
  End If
    For Each strFile In objDIR.Files
        WScript.Echo Chr(34) & strFile.Path & Chr(34) & "," &_
        Chr(34) & strFile.Size & Chr(34) & "," &_
        Chr(34) & strFile.DateLastModified & Chr(34) & "," &_
        Chr(34) & strFile.DateCreated & Chr(34) & "," &_
        Chr(34) & strFile.DateLastAccessed & Chr(34)
    Next 
End Sub 

然后從命令行這樣調用它。

c:\test> cscript //nologo myscript.vbs "c:\" > "C:\test\Output.csv"