在VB.net中讀取XML

Question

我用google搜索了最后一個小時左右沒有運氣（我想我也是一個偉大的Google員工！），所以我在這里。

我有一個XML文件，我用於我的程序設置，它看起來像這樣：

<?xml version="1.0" encoding="utf-8"?>
<config>
    <store>
        <number>0323</number>
        <address>address</address>
        <phone>phone</phone>
    </store>

    <emailsettings>
        <emailfrom>emailfrom</emailfrom>
        <emailpass>pass</emailpass>
        <emailsubject>received</emailsubject>
        <smtpserver>smtp.gmail.com</smtpserver>
        <smtpport>587</smtpport>
        <enablessl>true</enablessl>
        <emailbody>package received</emailbody>
    </emailsettings>
    <dbconfig>
        <dbpath>path</dbpath>
    </dbconfig>
</config>

我如何使用vb.net獲取每個元素並返回我想要的特定值？ 本身，我想在textbox1中返回<number> （在<store> ），在textbox2中返回<emailbody> （在<emailsettings> ）。

幫助pleaseeeeee！ 謝謝 ：）

Answer 1

啊，一個用Framework 3.5展示VB.NET強大的XML特性的完美例子：

Sub Main()
    Dim xml = XDocument.Load("config.xml")
    Console.WriteLine("Number: " & xml.<config>.<store>.<number>.Value)
    Console.WriteLine("Body: " & xml.<config>.<emailsettings>.<emailbody>.Value)
End Sub

收益率：

Number: 0323
Body: package received

Answer 2

這是一個使用VB.Net XML Literal支持的Console應用程序。

Module Module1

    Sub Main()

        Dim xElem = <config>
                       <store>
                           <number>0323</number>
                           <address>address</address>
                           <phone>phone</phone>
                       </store>

                       <emailsettings>
                           <emailfrom>emailfrom</emailfrom>
                           <emailpass>pass</emailpass>
                           <emailsubject>received</emailsubject>
                           <smtpserver>smtp.gmail.com</smtpserver>
                           <smtpport>587</smtpport>
                           <enablessl>true</enablessl>
                           <emailbody>package received</emailbody>
                       </emailsettings>
                       <dbconfig>
                           <dbpath>path</dbpath>
                       </dbconfig>
                   </config>

        Dim number = xElem.<store>.<number>.Value
        Dim emailbody = xElem.<emailsettings>.<emailbody>.Value

        Console.WriteLine(String.Format("Number={0}", number))
        Console.WriteLine(String.Format("emailbody={0}", emailbody))
        Console.ReadLine()

        '--- What it'd look like if you loaded from a file using XDocument.Load
        Dim xDoc = XDocument.Load(New IO.StringReader(xElem.ToString))
        number = xDoc.Root.<store>.<number>.Value
        emailbody = xDoc.Root.<emailsettings>.<emailbody>.Value

        Console.WriteLine(String.Format("Number={0}", number))
        Console.WriteLine(String.Format("emailbody={0}", emailbody))
        Console.ReadLine()


    End Sub

End Module

結果將是：

 Number=0323 emailbody=package received Number=0323 emailbody=package received 

Answer 3

您可以使用XML序列化。 創建表示XML結構的類，並使用XML序列化類對數據進行反序列化。 完成后，您可以使用應用程序中的數據。

以下是MSDN示例的鏈接：

http://msdn.microsoft.com/en-us/library/ms950721.aspx

Answer 4

如果您熟悉數據集和數據表，這是一種簡單的方法：

Dim DS As New DataSet
DS.ReadXml("Data.xml")

DataSet可以讀取任何XML。 我甚至用它來調用支持rest的XML服務。