如何將像3 10 ^ -20這樣的字符串轉換為Perl中的數字？

Question

我有一個文件，其中包含如下所示的數字列表：

10^-92
2 10^-14
10^-105
3 10^-20

為了進一步解釋， 10^-92基本上是1E-92 10^-92 2 10^-14是2E^-14 。 有沒有一種緊湊的方法將上述文件中的數字轉換為Perl號碼？ 最后，我想用數字對這些數字進行排序。

Answer 1

如果所有數字都需要相同的轉換成為Perl的數字，為什么不使用正則表達式替換：

use 5.010;

my @nums = ('10^-92', '2 10^-14', '10^-105', '3 10^-20');

s{ (\d*) \s* 10\^ }{ ($1 || 1) . 'e' }xe for @nums;

say "@nums";  # 1e-92 2e-14 1e-105 3e-20

Answer 2

如果你想要一個Perl號碼，只需直接找到沒有eval的號碼。 存儲您提取的數字部分，並在緩存鍵排序中使用它們：

use 5.010;

while( <DATA> )
    {
    chomp;

    m/
        (?:
            (?<coefficient> \d+ (?:\.\d+)? )
            \s+
        )?

        (?<base> (\d+) )

        \^

        (?<exponent> -?\d+ )
    /x;


    push @numbers,
        [ ( $+{coefficient} // 1 ), $+{exponent}, $_ ];
    }

my @sorted = sort {
    $a->[1] <=> $b->[1]
        ||
    $a->[0] <=> $b->[0]
    } @numbers;

foreach my $number ( @sorted )
    {
    print "$number->[-1]\n";
    }

__DATA__
10^-92
2 10^-14
10^-105
3 10^-20

你可以把它歸結為Schwartzian變換：

use 5.010;

print
map {
    $_->[-1]
    }
sort {
    $a->[1] <=> $b->[1]
        ||
    $a->[0] <=> $b->[0]
    }
map {
    m/
        (?:(?<c> \d+ (?:\.\d+)? ) \s+ )? # coefficient
        (?<b> (\d+) )                    # base
        \^
        (?<e> -?\d+ )                    # exponent
    /x;
    [ ( $+{c} // 1 ), $+{e}, $_ ];
    } <DATA>;


__DATA__
10^-92
2 10^-14
10^-105
3 10^-20

Answer 3

$ perl -ne 's/ /*/;s/\^/E/;print "\n".eval $_' file

2e-13
1e-91
2e-13
1e-104
3e-19