在Actionscript 3中擴展數組（Flex）

Question

我正在嘗試為Array做出一個非常特殊的變化。 當我有以下內容時：

public class TileArray extends Array {
   // Intentionally empty - I get the error regardless
}

為什么我不能這樣做？

var tl:TileArray = [1,2,3];

盡管我能做到這一點

var ar:Array = [1,2,3];

我收到的錯誤是這樣的：

Implicit coercion of a value with static type Array to a possibly unrelated type

Answer 1

您可以編寫自己的類來公開Array的所有方法，而不是擴展Array。 通過使用Proxy類，您可以將所有默認Array方法重定向到內部數組，但仍可以靈活地添加自己的方法：

package
{
    import flash.utils.flash_proxy;
    import flash.utils.Proxy;

    use namespace flash_proxy;

    dynamic public class ExampleArray extends Proxy
    {
        private var _array:Array;

        public function ExampleArray(...parameters)
        {
            _array = parameters;
        }

        override flash_proxy function callProperty( name:*, ...rest):* 
        {
            return _array[name].apply(_array, rest);

        }

        override flash_proxy function getProperty(name:*):* 
        {
            return _array[name];
        }

        override flash_proxy function setProperty(name:*, value:*):void 
        {
            _array[name] = value;
        }

        public function getSmallestElement():*
        {
            var helper:Array = _array.concat().sort();
            return helper[0];
        }

    }
}

例：

var test:ExampleArray = new ExampleArray(8,7,6,5,4,3,2,1);
trace( test.getSmallestElement()); // 1
test.sort();
trace(test); // 1,2,3,4,5,6,7,8 

Answer 2

[]僅創建一個數組。 它不能用於創建Array的子​​類。

使用新功能“擴展”Array的好方法是編寫操作常規數組的獨立實用程序函數。 最重要的是，這將允許您對任何數組執行任何操作，而不僅限於使用您的子類創建的數組。

這是一個包含Arrays實用函數的類的簡單示例：

package com.example.utils
{
    public class ArrayUtil
    {
        public static function traceArray( array:Array ):void
        {
            trace( array.length, "[" + array + "]" );
        }
    }
}

用法：

ArrayUtil.traceArray( [1, 2, 3] ); //output: 3 [1,2,3]

Answer 3

[1,2,3]是new Array(1,2,3)簡寫（或語法糖new Array(1,2,3) 。 考慮到這一點，您的代碼失敗似乎更為明顯。

每個TileArray都是一個Array ，因為TileArray擴展了Array ，但反之則不然：並非每個Array都是TileArray 。 因此，您無法傳遞期望TileArray的Array 。 這就是你得到編譯器錯誤的原因。

轉換只會將錯誤從編譯時推遲到運行時，因為對象的實際類型是Array ，這實際上與TileArray無關。

如果您想擴展Array功能（並且還能夠添加一些語法糖），您可能需要查看擴展Proxy ，因為它已經建議。 請記住，它的性能較差，所以如果你計划大量使用這個類，這可能不是最好的主意。