如何從存儲過程返回多行？ (甲骨文 PL/SQL)

Question

我想創建一個帶有一個參數的存儲過程，它將根據參數返回不同的記錄集。 這樣做的方法是什么？ 我可以從普通的 SQL 調用它嗎？

Answer 1

以下是如何構建一個 function，它返回一個可以像查詢表一樣查詢的結果集：

SQL> create type emp_obj is object (empno number, ename varchar2(10));
  2  /

Type created.

SQL> create type emp_tab is table of emp_obj;
  2  /

Type created.

SQL> create or replace function all_emps return emp_tab
  2  is
  3     l_emp_tab emp_tab := emp_tab();
  4     n integer := 0;
  5  begin
  6     for r in (select empno, ename from emp)
  7     loop
  8        l_emp_tab.extend;
  9        n := n + 1;
 10       l_emp_tab(n) := emp_obj(r.empno, r.ename);
 11     end loop;
 12     return l_emp_tab;
 13  end;
 14  /

Function created.

SQL> select * from table (all_emps);

     EMPNO ENAME
---------- ----------
      7369 SMITH
      7499 ALLEN
      7521 WARD
      7566 JONES
      7654 MARTIN
      7698 BLAKE
      7782 CLARK
      7788 SCOTT
      7839 KING
      7844 TURNER
      7902 FORD
      7934 MILLER

Answer 2

我想你想返回一個 REFCURSOR：

create function test_cursor 
            return sys_refcursor
            is
                    c_result sys_refcursor;
            begin
                    open c_result for
                    select * from dual;
                    return c_result;
            end;

更新：如果您需要從 SQL 調用它，請使用 @Tony Andrews 建議的表 function。

Answer 3

您可以使用 Oracle 流水線函數

基本上，如果您希望 PLSQL（或 java 或 c）例程成為數據的“源”——而不是表格——您將使用流水線 function。

簡單示例 - 生成一些隨機數據
您如何根據輸入參數創建 N 個唯一的隨機數？

create type array
as table of number;


create function  gen_numbers(n in number default null)
return array
PIPELINED
as
begin
  for i in 1 .. nvl(n,999999999)
  loop
     pipe row(i);
 end loop;
 return;
end;

假設我們需要三行來放置某物。 我們現在可以通過以下兩種方式之一來做到這一點：

select * from TABLE(gen_numbers(3));

COLUMN_VALUE

---

       1
       2
       3

要么

select * from TABLE(gen_numbers)
 where rownum <= 3;

COLUMN_VALUE

---

       1
       2
       3

流水線函數1 流水線函數2

Answer 4

如果您想在普通 SQL 中使用它，我會讓存儲過程用結果行填充表或臨時表（或 go 對於@Tony Andrews 方法）。
如果你想使用@Thilo 的解決方案，你必須使用 PL/SQL 循環 cursor。 這里有一個例子：（我使用了一個過程而不是 function，就像@Thilo 所做的那樣）

create or replace procedure myprocedure(retval in out sys_refcursor) is
begin
  open retval for
    select TABLE_NAME from user_tables;
end myprocedure;

 declare 
   myrefcur sys_refcursor;
   tablename user_tables.TABLE_NAME%type;
 begin
   myprocedure(myrefcur);
   loop
     fetch myrefcur into tablename;
     exit when myrefcur%notfound;
     dbms_output.put_line(tablename);
   end loop;
   close myrefcur;
 end;

Answer 5

create procedure <procedure_name>(p_cur out sys_refcursor) as begin open p_cur for select * from <table_name> end;