Flex / Actionscript：將數據從自定義類傳遞到主應用程序？

Question

好的，這聽起來有些愚蠢，但我是Flex編程的完整入門者。

我有一個帶有主.mxml文件的應用程序，以及一個我從.mxml調用的特定類Foo

在Foo中，我創建一個URLRequest並偵聽Complete事件。 然后，我在Foo函數中發現了返回的數據，但是我不知道如何將其傳遞給applicaton的.mxml部分！ 我研究了ArrayCollections，但似乎無法理解它們如何工作以及是否有幫助。 沒有辦法從類內部修改具有全局作用域的變量嗎？

Answer 1

這聽起來像是一個小型應用程序，但是如果它是大型應用程序，則可能需要查看像RobotLegs這樣的微型框架。

如果您有Foo類擴展EventDispatcher，則它將能夠發送事件，並使主MXML應用程序偵聽所述事件。

package com.example
{
    import flash.events.EventDispatcher;
    import com.example.events.MyEvent;

    public class Foo extends EventDispatcher 
    {
        public function doAction():void 
        {
            var someData:String = "blah";
            dispatchEvent(new MyEvent(MyEvent.SOMETHING_HAPPENED, someData));
        }
    }
}

具有有效負載的自定義事件（在這種情況下為字符串）

package com.example.events 
{
    import flash.events.Event;

    public class MyEvent extends Event 
    {
        static public const SOMETHING_HAPPENED:String = "somethingHappened";

        private var _myData:String;

        public function get myData():String 
        {
            return _myData;
        }

        public function MyEvent(type:String, myData:String, bubbles:Boolean=false, cancelable:Boolean=false) 
        {
            _myData = myData;
            super(type, bubbles, cancelable);
        }

        override public function clone():Event 
        {
            return new MyEvent(type, myData, bubbles, cancelable);
        }
    }
}

從主文件處理Foo類：

public function EventDispatcherExample() {
    var foo:Foo = new Foo();
    foo.addEventListener(MyEvent.SOMETHING_HAPPENED, actionHandler);
    foo.doAction();
}

private function actionHandler(e:MyEvent):void {
    trace("my data is: " + e.myData);
}

Answer 2

import mx.core.FlexGlobals;
FlexGlobals.toplevelApplication.varName;

Answer 3

您的Foo類可以調度事件，並且在您的main.mxml中包含一些內容以偵聽該事件。 我確信我可以創建一個例子。 我認為這是在Flex文檔中的客戶事件下。 假設我理解這個問題。

Answer 4

正如約翰所說，活動是您的最佳選擇。

如果您想要一些示例代碼，我在這里提供了一個類似的問題： 從彈出窗口到主應用程序的數據？

Answer 5

如前所述，事件可能是最好的方法。 另一種方法是調度這樣的事件

dispatchEvent(new Event('somethingHappened'));

並在您的類中為需要獲取的數據創建一個get方法。

那么您在主應用程序中要做的就是

var foo:Foo = new Foo();
foo.addEventListener('somethingHappened', actionHandler);

private function actionHandler(e:Event):void 
{
    trace(foo.memberData);
}

如果數據仍然是類成員，並且您希望避免創建新的事件類，則這種方法可能更合適。