使用 XSLT 創建帶有嵌套粗體/斜體標簽的 XSL-FO

Question

我正在創建 xslt 文件，它應該將我的 xml 轉換為 xsl-fo。

XML 是這樣的：

<doc>
  <par>
    <point>
      <text>some text</text>
    </point>
  </par>
</doc>

當然，文檔中有很多段落和要點。 例如，我想增加格式化“一些文本”的可能性

<bold>bolded text</bold> and <italic>italic</italic>

應該給

<fo:block><fo:inline font-weight="bold">bolded text</fo:inline> and <fo:inline font-style="italic">italic</fo:inline>

現在我有一個非常簡單的 xslt 文檔，如下所示：

<xsl:stylesheet version="1.1" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" exclude-result-prefixes="fo">
  <xsl:output method="xml" version="1.0" omit-xml-declaration="no" indent="yes"/>
  <xsl:param name="versionParam" select="'1.0'"/> 
  <xsl:template match="doc">
    <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
      <fo:layout-master-set>
        <fo:simple-page-master master-name="simpleA4" page-height="29.7cm" page-width="21cm" margin-top="2cm" margin-bottom="2cm" margin-left="2cm" margin-right="2cm">
          <fo:region-body margin="2cm"/>
          <fo:region-before margin="0.2cm" extent="1.5cm"/>
        </fo:simple-page-master>
      </fo:layout-master-set>
      <fo:page-sequence master-reference="simpleA4">
        <fo:static-content flow-name="xsl-region-before"  margin-right="1cm"> 
            <fo:block text-align="start" margin-top="0.2cm">
            <fo:block text-align="end" margin-top="0.2cm">
                Page <fo:page-number/> of <fo:page-number-citation ref-id="terminator"/>
            </fo:block>
        </fo:static-content>
        <fo:flow flow-name="xsl-region-body">
          <xsl:apply-templates select="par/point"/>
          <fo:block id="terminator"/>
        </fo:flow>
      </fo:page-sequence>
    </fo:root>
  </xsl:template>
  <xsl:template match="point">
    <fo:block font-size="16pt" space-after="5mm">
        <xsl:value-of select="tresc"/>
    </fo:block>
  </xsl:template>
</xsl:stylesheet>

我應該添加另一個模板（粗體、斜體）嗎？ 我應該如何在“文本”節點中調用它？

我找到了一些解決方案：

<xsl:template match="//bold">
    <fo:inline font-weight="bold">
        <xsl:value-of select="current()"></xsl:value-of>
    </fo:inline>
</xsl:template>

但這對我不起作用。 Output xsl-fo 不包含任何 fo:inline。

Answer 1

看看這個例子。 它清楚地顯示了如何處理內聯節點。

[XSLT 1.0]

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:output indent="yes"/>

    <xsl:template match="doc">
        <fo:root>
            <fo:page-sequence>
                <fo:flow>
                    <xsl:apply-templates select="par/point"/>
                </fo:flow>
            </fo:page-sequence>
        </fo:root>
    </xsl:template>

    <xsl:template match="point">
        <fo:block font-size="16pt" space-after="5mm">
            <xsl:apply-templates select="node()"/>
        </fo:block>
    </xsl:template>

    <xsl:template match="bold">
        <fo:inline font-weight="bold">
            <xsl:apply-templates select="node()"/>
        </fo:inline>  
    </xsl:template>

    <xsl:template match="italic">
        <fo:inline font-style="italic">
            <xsl:apply-templates select="node()"/>
        </fo:inline>
    </xsl:template>

</xsl:stylesheet>

給定：

<doc>
    <par>
        <point>
            <text>some <bold>bold</bold></text>
        </point>
    </par>
    <par>
        <point>
            <text>some <italic>italic <bold>bolded</bold></italic></text>
        </point>
    </par>
</doc>

產生：

<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:page-sequence>
      <fo:flow>
         <fo:block font-size="16pt" space-after="5mm">
            some <fo:inline font-weight="bold">bold</fo:inline>
               </fo:block>
         <fo:block font-size="16pt" space-after="5mm">
            some <fo:inline font-style="italic">italic <fo:inline font-weight="bold">bolded</fo:inline>
            </fo:inline>
               </fo:block>
      </fo:flow>
   </fo:page-sequence>
</fo:root>