Groovy 閉包可以擴展抽象 class

Question

我有一個抽象的 Java class 需要有一個方法onMessage來實現。 我知道閉包可以使用as關鍵字輕松實現 Java 接口，但它如何擴展抽象 Java class？

如果它不能擴展它，那么在 Groovy 的這種情況下，最好的解決方法是什么？

這是我在 Java 中的用法，我正在尋找可以在 Groovy 中完成的類似操作。

MessageCallback callback = new MessageCallback() {
            @Override
            public void onMessage(Message message) {
                dosomething();
            }
        };

其中消息回調是我的抽象 class，我想在 Groovy 中以類似的方式使用它。

Answer 1

我相信你應該能夠做到：

def callback = [ onMessage:{ message -> doSomething() } ] as MessageCallback

那不行嗎？

編輯

要從 Map 方法調用抽象 class，我能找到的唯一方法是：

// Dummy class for testing
abstract class MessageTest {
  abstract void onMessage( msg ) ;
  void done() { println "DONE!" }
}

// Create a Proxied instance of our class, with an empty onMessage method
def p = [ onMessage:{ msg -> } ] as MessageTest

// Then overwrite the method once we have access to the Proxy object p
p.metaClass.onMessage = { msg -> println msg ; p.done() }

// Test
p.onMessage( 'woo' )

Answer 2

喲可以這樣做：

在任何 class 中實現一個方法：

public MessageTest messageTest(Closure callback) {
    return new MessageTest() {
        @Override
        public void onMessage(Message message) {
            callback.call(message)
        }
    }
}

在主要方法中的主要 class 中：

def outerMessage

MessageTest messageTest = messageTest() {message ->
    outerMessage = message
    println "innerMessage: $message"
}

messageTest.onMessage("This is the message...")
println "outerMessage: $outerMessage"

您的 output 應該顯示：

innerMessage: This is the message...
outerMessage: This is the message...

Answer 3

基於@tim_yates，這是一個從閉包創建抽象 class 的 object 的方法版本。 我需要這樣的東西才能在一行中實例化這樣的 object。

// Dummy class for testing
abstract class MessageTest {
  abstract void onMessage( msg ) ;
  void done() { println "DONE!" }
}

MessageTest createMessageTest(Closure closure) {
  // Create a Proxied instance of our class, with an empty onMessage method
  def p = [ onMessage:{ msg -> } ] as MessageTest

  // Then overwrite the method once we have access to the Proxy object p
  p.metaClass.onMessage = closure
  return p
}

// Create
MessageTest mt = createMessageTest { msg -> 
  println msg ; 
  done() 
}

// Test
mt.onMessage( 'woo' )