如何將列的數據傳輸到行（使用awk）？

Question

我有一個這樣的文件：

n A B C D 
1 01 02 01 01
2 02 02 01 01

我想逐行傳輸列，所以輸出應該是這樣的：

n 1 2
A 01 02
B 02 02
C 01 01 
D 01 01

我寫了這個命令：

awk '{ for (i=1;i<=NF;i++ ) printf $i " " }' file.txt > out-file.txt

問題是這個命令把所有東西都放在了一行！ 所以輸出是這樣的：

n 1 2 A 01 02 B 02 02 C 01 01 D 01 01

Answer 1

這是對 gawk 擴展的數組數組的使用：

tp(){ awk '{for(i=1;i<=NF;i++)a[i][NR]=$i}END{for(i in a)for(j in a[i])printf"%s"(j==NR?"\n":FS),a[i][j]}' "FS=${1-$'\t'}";}

另一種選擇是使用rs （它是 macOS 附帶的 BSD 實用程序）：

$ cat /tmp/a
n A B C D
1 01 02 01 01
2 02 02 01 01
$ rs -c' ' -C' ' -T</tmp/a|sed 's/.$//'
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

-c更改輸入列分隔符， -C更改輸出列分隔符， -T轉置行和列。

當使用-C指定輸出列分隔符時，會在每個輸出行的末尾添加一個額外的列分隔符，但您可以使用sed 's/.$//'將其刪除：

$ seq 4|paste -d, - -|rs -c, -C, -T
1,3,
2,4,
$ seq 4|paste -d, - -|rs -c, -C, -T|sed 's/.$//'
1,3
2,4

如果第一行以一個或多個空列結尾，則rs命令會失敗，因為列數是根據第一行的列數確定的：

$ rs -c, -C, -T<<<$'1,\n3,4'
1,3,4,

Answer 2

這可能有效：

awk '{
       for (f = 1; f <= NF; f++) { a[NR, f] = $f } 
     }
     NF > nf { nf = NF }
     END {
       for (f = 1; f <= nf; f++) {
           for (r = 1; r <= NR; r++) {
               printf a[r, f] (r==NR ? RS : FS)
           }
       }
    }' YOURINPUT

在行動中看到它@Ideone 。

Answer 3

將此腳本另存為 transpose.awk 和chmod u+x transpose.awk 。 這是對Tim Sherwood 的transpose的修改。

#!/usr/bin/gawk -f

BEGIN {
    max_x =0;
    max_y =0;
}

{
    max_y++;
    for( i=1; i<=NF; i++ )
    {
        if (i>max_x) max_x=i;
        A[i,max_y] = $i;
    }
}

END {
    for ( x=1; x<=max_x; x++ )
    {
        for ( y=1; y<=max_y; y++ )
        {
            if ( (x,y) in A ) printf "%s",A[x,y];
            if ( y!=max_y ) printf " ";
        }
        printf "\n";
    }
}

例子：

$ ./transpose.awk example
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01

Answer 4

這是一個不同的解決方案，最后只涉及一個 for 循環：

{ for (i=1; i<=NF; i++) col[i] = col[i] " " $i }
END { 
    for (i=1; i<=NF; i++) { 
        sub(/^ /, "", col[i]); 
        print col[i] 
    } 
}

討論

• 此解決方案使用一維數組col ，它存儲整列的值。 col[1]是第一列。
• 對於每一行，我們將列附加到 col[i]。 因為我們盲目追加，所以col[i]值將包含一個前導空格。
• 最后， sub() 函數在打印出列（現在是一行）之前刪除前導空格

Answer 5

好吧，沒有 awk 我們可以用cat做到這一點：

for x in `cat filename`
do
echo $x
done

使用此腳本，結果將出現在 cols 中。