Perl：將STDOUT重定向到兩個文件

Question

如何在我的Perl腳本中將STDOUT流重定向到兩個文件（重復項）？ 目前我只是流入一個日志文件：

open(STDOUT, ">$out_file") or die "Can't open $out_file: $!\n";

我需要改變什么？ 謝謝。

Answer 1

您也可以使用IO::Tee 。

use strict;
use warnings;
use IO::Tee;

open(my $fh1,">","tee1") or die $!;
open(my $fh2,">","tee2") or die $!;

my $tee=IO::Tee->new($fh1,$fh2);

select $tee; #This makes $tee the default handle.

print "Hey!\n"; #Because of the select, you don't have to do print $tee "Hey!\n"

是的，輸出有效：

> cat tee1
Hey!
> cat tee2
Hey!

Answer 2

File :: Tee提供您所需的功能。

use File::Tee qw( tee );
tee(STDOUT, '>', 'stdout.txt');

Answer 3

使用tee PerlIO層。

use PerlIO::Util;
*STDOUT->push_layer(tee => "/tmp/bar");
print "data\n";

$ perl tee_script.pl > /tmp/foo
$ cat /tmp/foo
data
$ cat /tmp/bar
data

Answer 4

如果您使用的是類Unix系統，請使用tee實用程序。

$ perl -le 'print "Hello, world"' | tee /tmp/foo /tmp/bar
Hello, world

$ cat /tmp/foo /tmp/bar
Hello, world
Hello, world

要在程序中設置此復制，請從STDOUT到外部T形過程設置管道。 通過"|-" open使這很容易。

#! /usr/bin/env perl

use strict;
use warnings;

my @copies = qw( /tmp/foo /tmp/bar );

open STDOUT, "|-", "tee", @copies or die "$0: tee failed: $!";

print "Hello, world!\n";

close STDOUT or warn "$0: close: $!";

演示：

$ ./stdout-copies-demo
Hello, world!

$ cat /tmp/foo /tmp/bar
Hello, world!
Hello, world!