在畫布上畫一條自定義樣式（delphi）

Question

我需要在畫布上繪制一些線條，但是我需要使用自定義樣式，沒有標准樣式作為實體，點，...

例如，我需要畫一條線作為“__。__。_ ”或“ ._。_。_。_”。 我所有的線都是破折號和點的組合，我需要設置短划線和破折號，點寬。

我不想使用GDI +或其他外部庫...

有一個簡單的方法嗎？

Answer 1

您可以使用普通GDI執行此操作：

procedure TForm1.FormPaint(Sender: TObject);
const
  pattern: array[0..3] of cardinal = (10, 1, 1, 1);
var
  lb: TLogBrush;
  pen, oldpen: HPEN;
begin
  lb.lbStyle := BS_SOLID;
  lb.lbColor := RGB(255, 0, 0);
  pen := ExtCreatePen(PS_COSMETIC or PS_USERSTYLE, 1, lb, length(pattern), @pattern);
  if pen <> 0 then
    try
      oldpen := SelectObject(Canvas.Handle, pen);
      Canvas.MoveTo(0, 0);
      Canvas.LineTo(ClientWidth, ClientHeight);
      SelectObject(Canvas.Handle, oldpen);
    finally
      DeleteObject(pen);
    end;
end;

Answer 2

您也可以使用LineDDA API。 確定Pen造型（由Andreas Rejbrand提供建議）要快得多，但LineDDA允許您以不同的顏色繪制線條的部分。

var
  DottedLineDrawCounter: Integer;

procedure DDAProc(AX, AY: Integer; ACanvas: TCanvas); stdcall;
begin
  if DottedLineDrawCounter mod 4 = 0 then
    ACanvas.Pixels[AX, AY] := clRed
  else
    ACanvas.Pixels[AX, AY] := clBlack;
  Inc(DottedLineDrawCounter);
end;

...
begin
  // Usage
  DottedLineDrawCounter := 0;
  LineDDA(X1, Y1, X2, Y2, @DDAProc, LPARAM(Canvas));
end;