通过目录树递归的Perl脚本

Question

I want to write a Perl script that starts at the top of a directory tree (provided in the command line arguments) and recursively moves through each sub-directory, performing a certain action on each file.

I'm using finddepth for this, however it does not seem to work when I run the script on a directory that is two levels or more from the base directory.

Here is my code:

#!/usr/local/bin/perl -w

use strict;

use File::Copy;
use File::Find;
use File::Basename;
use File::Path;

finddepth(\&file_list, @ARGV);

sub file_list {

    my ($file_path, $name, $path, $suffix);

    $file_path = $File::Find::name;

    ($name, $path, $suffix) = fileparse($file_path, /\.*/);

    my $fullname = $name . $suffix;
    my $file = $fullname;

    if ($file =~ /^[^\.].*[^\.pl]$/) {

        copy($file, "$file.orig");

        open(FILE, "$file");
        my @file_data = <FILE>;
        close(FILE);

        open(FOUT, ">$file") or die " \n File cannot be opened !";

        foreach my $line (@file_data) {
            if ($line =~ /^\s+Error:/) {
                $line =~ s/([^-]\d+)/ \*\*/gc;
                print FOUT $line;
            }
            else {
                print FOUT $line;
            }
        }
        close(FOUT);
    }
}

The following warnings/errors are consistently thrown:

1. Read on closed filehandle
2. File cannot be opened !

I can't seem to figure out why this is happening. I've tried to make my question as specific as possible. Please let me know if you need any more information. Thank you.

Answer 1

You can't open the file because $file happens to be a directory at that point in time, so you'll need to add a check for that.

It's probably worth adding an or die statement when opening the file for reading.

Also note that File::Find sets $_ to the current file name, so the 5 lines you take to produce $file are actually unnecessary.

Answer 2

There are a few problems with your code.

• use warnings is preferable to the command-line -w

• Declare your variables at their first point of use, not in a block at the top of the the subroutine

• Use the three-parameter form of open , and lexical file handles

• When checking the status of an open call, put the built-in variable $! in the die string so that you know why the open failed

• Don't put scalar variables inside double quotes. It is probably unnecessary and under some circumstances can break your code. It is highly unlikely to do anything you want

This rewrite of your program uses use autodie to avoid the need for explicit open ... or die $! statements. It uses rename to change the name of the file instead of copying it and overwriting the original.

Instead of reading the entire file into memory, I open the renamed file and read it line by line, editing and writing each line to the new file

I have written it so that it ignores files that begin with a dot or end with .pl - I hope that's right. I am also very dubious about your substitution s/[^-]\\d+/ **/g which looks for a sequence of digits preceded by a character that isn't a hyphen; is that right?

#!/usr/local/bin/perl

use strict;
use warnings;

use autodie;
no autodie 'unlink';

use File::Find 'finddepth';

finddepth(\&file_list, @ARGV);

sub file_list {

  return unless -f;
  return if /^\./ or /\.pl$/;

  my $file = $_;
  my $orig = "$file.orig";

  unlink $orig;
  rename $file, $orig;

  open my $infh, '<', $orig;
  open my $outfh, '>', $file;

  while (my $line = <$infh>) {
    if ($line =~ /^\s+Error:/) {
      $line =~ s/[^-]\d+/ **/g
    }
    print $outfh $line;
  }

  close $outfh;
}