perl脚本来计数Windows目录树中的文件

Question

I am new to perl scripting. I am trying to get the count of directories & subdirectories. So I have searched all the available help on scripting. But unable get the count of Subdirectories. Below is the script I used.

use strict;
use warnings;
use File::Slurp;

my @dirs            = ('.');
my $directory_count = 0;
my $file_count      = 0;
my $outfile         = 'log.txt';

open my $fh, '>', $outfile or die "can't create logfile; $!";
for my $dir (@dirs) {
    for my $file (read_dir ($dir)) {
        if ( -d "$dir/$file" ) {
            $directory_count++;
        }
        else {
            $file_count++;
        }
    }
    print $fh "Directories: $directory_count\n";
    print $fh "Files: $file_count\n";
}
close $fh;

Here, I am unable to identify where to change the command of dir with /s. Please help it will reduce lot of manual work.

Ravi

Answer 1

Never EVER write your own directory traversal. There are too many pitfalls, gotchas and edge cases. Things like path delimiters, files with spaces, alternate data streams, soft links, hard links, DFS paths... just don't do it.

Use File::Find or if you prefer File::Find::Rule .

As I prefer the former, I'll give an example:

use strict;
use warnings;

use File::Find;

my $dir_count;
my $file_count;

#find runs this for every file in it's traversal.
#$_ is 'current file'. $File::Find::Name is full path to file. 
sub count_stuff {
    if ( -d ) { $dir_count++ };
    if ( -f ) { $file_count++ };
}

find ( \&count_stuff, "." );

print "Dirs: $dir_count\n";
print "Files: $file_count\n";

Answer 2

Here is a script that does it: 1) without global variables; and 2) without adding another sub to the namespace.

#!/usr/bin/env perl

use strict;
use warnings;
use File::Find;

run(\@ARGV);

sub run {
    my $argv = shift;
    for my $dir ( @$argv ) {
        my $ret = count_files_and_directories( $dir );
        printf(
            "%s: %d files and %d directories\n",
            $dir,
            $ret->{files},
            $ret->{directories}
        );
    }
    return;
}

sub count_files_and_directories {
    my $top = shift;
    my %ret = (directories => 0, files => 0);
    find(
        {
            wanted => sub {
                -d and $ret{directories} += 1;
                -f and $ret{files} += 1;
            },
            no_chdir => 1,
        },
        $top,
    );
    \%ret;
}

Answer 3

It seems simpler to use File::Find::Rule .. For example:

use warnings;
use strict;
use File::Find::Rule;

my @files = File::Find::Rule->new->file->in('.');
my @dirs = File::Find::Rule->new->directory->in('.');