查找@括起来的文本并替换内部

Question

The problem:

Find pieces of text in a file enclosed by @ and replace the inside

Input:

@abc@ abc @ABC@
cba @cba CBA@

Deisred output:

абц abc АБЦ
cba цба ЦБА

I have the following:

#!/usr/bin/perl
use strict;
use warnings;
use Encode;
my $output;
open FILE,"<", 'test.txt';
while (<FILE>) {
    chomp(my @chars = split(//, $_));
    for (@chars) {
        my @char;
        $_ =~ s/a/chr(0x430)/eg;
        $_ =~ s/b/chr(0x431)/eg;
        $_ =~ s/c/chr(0x446)/eg;
        $_ =~ s/d/chr(0x434)/eg;
        $_ =~ s/e/chr(0x435)/eg;
        $_ =~ s/A/chr(0x410)/eg;
        $_ =~ s/B/chr(0x411)/eg;
        $_ =~ s/C/chr(0x426)/eg;
        push @char, $_;
        $output = join "", @char;
        print encode("utf-8",$output);}
print "\n";
}
close FILE;

But I'm stuck on how to process further

Thanks for help in advance!

Kluther

Answer 1

Here my solution. (you will fixed it, yes. It is prototype)

for (my $data = <DATA>){
    $data=~s/[@]([\s\w]+)[@]/func($1)/ge;
    print $data;
#   while($data=~m/[@]([\s\w]+)[@]/g){
#      print "marked: ",$1,"\n";
#      print "position:", pos();
#   }
#      print "not marked: ";
}
sub func{
   #do your magic here ;)
   return "<< @_ >>";
}
__DATA__
@abc@ abc @ABC@ cba @cba CBA@

What happens here?

First, I read data. You can do it yourself.

for (my $data = <DATA>){...}

Next, I need to search your pattern and replace it.
What should I do?

Use substition operator: s/pattern/replace/

But in interesting form:

s/pattern/func($1)/ge

Key g mean Global Search

Key e mean Evaluate

So, I think, that you need to write your own func function ;)

Maybe better to use transliteration operator: tr/listOfSymbolsToBeReplaced/listOfSymbolsThatBePlacedInstead/

Answer 2

Try this after $output is processed.

$output =~ s/\@//g;
my @split_output = split(//, $output);
$output = "";
my $len = scalar(@split_output) ;
while ($len--) {
    $output .= shift(@split_output);
}
print $output;

Answer 3

It can be done with a single regex and no splitting of the string:

use strict;
use warnings;
use Encode;

my %chars = (
    a => chr(0x430),
    b => chr(0x431),
    c => chr(0x446),
    d => chr(0x434),
    e => chr(0x435),
    A => chr(0x410),
    B => chr(0x411),
    C => chr(0x426),
);

my $regex = '(' . join ('|', keys %chars) . ')'; 


while (<DATA>) {
    1 while ($_ =~ s|\@(?!\s)[^@]*?\K$regex(?=[^@]*(?!\s)\@)|$chars{$1}|eg);
    print encode("utf-8",$_);
}

It does require repeated runs of the regex due to the overlapping nature of the matches.

Answer 4

With minimal changes to your algorithm you need to keep track of whether you are inside the @ marks or not. so add something like this

my $bConvert = 0;
chomp(my @chars = split(//, $_));
for (@chars) {
    my $char = $_;
    if (/@/) {
        $bConvert = ($bConvert + 1) % 2;
        next;
    }
    elsif ($bConvert) {
        $char =~ s/a/chr(0x430)/eg;
        $char =~ s/b/chr(0x431)/eg;
        $char =~ s/c/chr(0x446)/eg;
        $char =~ s/d/chr(0x434)/eg;
        $char =~ s/e/chr(0x435)/eg;
        $char =~ s/A/chr(0x410)/eg;
        $char =~ s/B/chr(0x411)/eg;
        $char =~ s/C/chr(0x426)/eg;
    }
    print encode("utf-8",$char);
}