循环VBA EXCEL列时忽略其他单元格值

Question

I'm going to start my problem with an example, as otherwise it will be too difficult to explain.

         A        B        C           D         E (ID)
1      word              letter                  1
       test              blabla                  
       other          
2      word              letter                  2
                         number
3      test              true                    3
4      other             false                   4
5      word              letter       Yes        5
6      word              letter       Yes        6
7      test              letter                  7

What's the goal?

If I'll try to explain the goal in words, it will be hard to understand; it's also hard to explain :) Anyway I also added my code, and if you are good with VBA you will understand the code better then the text.

IF a value (in this example: word) is also in other rows THEN we needs to check column C, AND IF there is a value in column C that we find more then once in column C (in this example: letter), we needs to recheck if in column A the value also appears more then once.

So I already made a SUB, AND IT WORKS ! :) BUT not if there are more values in a cell. So in the example when there is only 1 value in a cell, as in row 6 & 7, column D returns : YES

Here is my code so far.

Sub duplicates()

Dim source As Range
Dim source2 As Range

For Each source In Range("A1", Range("A" & Rows.Count).End(xlUp))
 If source.Value <> "" Then
    For Each source2 In Range("A1", Range("A" & Rows.Count).End(xlUp))


    If source.Value = source2.Value And source.Offset(0, 4).Value <> source2.Offset (0, 4).Value Then

        If source.Offset(0, 2).Value = source2.Offset(0, 2).Value Then

         source.Offset(0, 3) = "Yes"
        End If
    End If
    Next source2
  End If
 Next source
End Sub

So, we should return: YES in row 1 & 2 as well. Hope you understand my goal. Hope someone can help.

Answer 1

My proposal is as follows:

A) additional function would check each element of each cell passed to the function as array:

Function AnyEqual(ColA, ColB) As Boolean

Dim itemA, itemB
For Each itemA In ColA
    For Each itemB In ColB
    If itemA = itemB Then
        AnyEqual = True
        Exit Function
    End If
    Next
Next

End Function

B) Some changes are made in your code - put it inside For Each source2 loop instead your inner code:

If AnyEqual(Split(source, Chr(10)), Split(source2, Chr(10))) And _
    source.Offset(0, 4).Value <> source2.Offset(0, 4).Value Then

    If AnyEqual(Split(source.Offset(0, 2), Chr(10)), _
                   Split(source2.Offset(0, 2), Chr(10))) Then

        source.Offset(0, 3) = "Yes"
    End If
End If

Based on data you provided it seems it works fine. I hope it is what you were looking for as it was a bit complicated to understand your needs.