将if语句添加到cmd.exe脚本

Question

I have a cmd.exe script:

FOR /F "tokens=5 delims==<ms" %i IN ('ping -n 1 -4 host1.internal ^|find "Reply from"') DO @echo %i

Basically, it returns ping value to host1.internal without anything else. I want to add if else statement so that if returned value is empty space, then return 0.

I tried to do it like this: ... DO IF %i (@echo %i) IF NOT %i (@echo 0) , but it returns ( was unexpected at this time and that's quite confusing.
Thanks.

Answer 1

Try this:

@echo off&setlocal
FOR /F "tokens=5 delims==<ms" %%i IN ('ping -n 1 -4 host1.internal ^|find "Reply from"') DO set "replay=%%i"
if defined replay (echo(%replay%) else echo(0

.. same code for the command line:

FOR /F "tokens=5 delims==<ms" %i IN ('ping -n 1 -4 host1.internal ^|find "Reply from"') DO if "%i" equ "" (echo(0) else echo(%i

Answer 2

If FIND fails, then echo out a line that will parse into your desired output.

FOR /F "tokens=5 delims==<ms" %i IN ('ping -n 1 -4 host1.internal ^|find "Reply from"^|^|echo XmXmXmXm0') DO @echo %i

Explanation

FIND returns with success (ERRORLEVEL 0) if string is found, failure (ERRORLEVEL 1) if string is not found.

The && operator conditionally executes a command if the prior command succeeded, and || conditionally executes if the prior command failed. The || must be escaped as ^|^| for the same reason that your pipe is escaped. The ECHO is simply printing a line that has a 0 in the 5th token.

Answer 3

You can execute multiple statements inside DO this way:

@FOR /L %%i in (1, 1, 5) DO @(
@echo %%i
@IF %%i==1 (@echo First)
@IF NOT %%i==1 (@echo Other)
)

Each command in its line grouped by '()'. Hope this helps...

Answer 4

Not a direct answer to your question, but another way of achieving your goal (assuming it's a test if a host exists/is reachable) would be to use conditional execution:
ping -n 1 -4 host1.internal >nul && echo "Host replied" || echo "Host not replied"

This uses status returned by command (ping in this instance) to execute appropriate command - && means on success and || on failure. You could also use errorlevel tests, but I personally find conditionals more readable especially directly on command line.

Additional plus is it is not language dependent (ping returns localized strings for various languages in Win).

Answer 5

Here's another method to check success or failure of ping.

@echo off
ping -n 1 -4 host1.internal >nul && (echo ping succeeded) || (echo ping failed)