SAS使用转置的多个标志

Question

I seek your help in creating the following table in SAS.

I have this table:

Policy no   Policy type ID_Payor1   ID_Payor2   ID_Insured1 ID_Insured2 ID_Owner1   ID_Owner2
123 P1  A   -   B   -   A   -
124 P2  B   -   -   -   -   -
124 P1  A   -   C   -   C   -

What I am looking to create is something like this that would consolidate numbers of policytypes that each ID has:

ID  Countflag_P1_Payor  Countflag_P1_Owner  Countflag_P1_Insured    Countflag_P2_Payor  Countflag_P2_Owner  Countflag_P2_Insured    
A   2   1   0   0   0   0   
B   0   0   1   1   0   0   
C   0   1   1   0   0   0   

Really would appreacite your help..

Thank you,

Answer 1

I think you want a proc freq or summary here to begin with to accumulate the counts. Creating a format for the ABC and using the preloadfmt option with proc summary seems to be the way to go.

The reason you want to create the format and do the proc summary that way is because you need to generate a dataset that has counts for A, B, and C for every policy_type -- even if the combinations don't exist. Like there aren't any C for ID_payor1 in your sample data, but you still want to generate rows that show a 0 count for C in that column.

    data table1;
 input Policy_no  
       Policy_type $ ID_Payor1 $ ID_Payor2 $ 
       ID_Insured1  $ ID_Insured2 $  ID_Owner1 $  ID_Owner2  $;
 datalines;
123 P1 A . B . A .
124 P2 B . . . . .
124 P1 A . C . C .
;


proc format;
   value $abc
            'A'='A'
            'B'='B'
            'C'='C'
            '.'='-'
    ;
run;

proc summary data=table1 completetypes nway;
   class  ID_Payor1 ID_Payor2 
          ID_Insured1 ID_Insured2 ID_Owner1 
          ID_Owner2 /preloadfmt missing;
   class policy_type;
   types policy_type * (ID_Payor1 ID_Payor2 ID_Insured1
                        ID_Insured2 ID_Owner1 ID_Owner2);
   output out=sumt1;
   format ID_Payor1 ID_Payor2 ID_Insured1 ID_Insured2 ID_Owner1 ID_Owner2 $abc.;
run;


proc print data=sumt1;

At this point your sumt1 dataset has for every column a freq count for AB and C (and missing as -) by each variable and P1 and P2. It's not nearly what you want yet but now is ready to be transposed. This dataset is too big to print here -- it's long rather than wide and has a lot of missing values in columns. But check out the results of the proc print at that point to see what you're getting.

For transposing multiple columns, we need to run proc transpose once on each column and then merge the results. A macro seems the way to go here.

Before transposing I'm also subsetting the large dataset so we only have rows that contain data for the column we're transposing.

%global freqtables;

%MACRO transall(mCol);

   data tmp_col;   
    set sumt1; 
     if &mCol. in ('A','B','C');

   proc transpose data=tmp_col 
                  out=outTrans_&mCol.(rename= &mCol.=IDabc) prefix=&mCol._;
      by &mCol.;
      id policy_type;
      var _FREQ_;
   run;

   %let freqtables = &freqtables outTrans_&mCol.(drop= _NAME_); 
     %* using freqtables macro variable to autogenerate a list;
     %* of tables for merging later;
%MEND transall;

%transall(ID_Payor1);
     %transall(ID_Payor2);
     %transall(ID_Insured1);
     %transall(ID_Insured2);
     %transall(ID_Owner1);
     %transall(ID_Owner2);   

*bonus points for creating another macro to loop through your variables; *instead of the above -- especially if you have many more columns;

data combined_counts;
        merge &freqtables;
        by IDabc;
       run;
proc print data=combined_counts; 

At this point you should have a table like the one you are looking for.