正确的zsh shell命令擒纵机构

Question

I have a pretty powerful trick I'm trying to do to save every command I ever type:

function zshaddhistory() {
    COMMAND_STR=${1%%$'\n'}
    [[ ( -z $COMMAND_STR ) || ( $COMMAND_STR =~ hist(ory)? ) || \
        ( $COMMAND_STR =~ ^l(s\|l\|a)?$ ) || \
        ( $COMMAND_STR =~ ^(d\|gd\|git\ diff\|glp\|gg)$ ) \
    ]] && return 1
    # do not do anything on common commands

    # do the needful
    echo "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history

    # rest is supposedly "default" zshaddhistory() (except it ain't)
    print -Sr ${COMMAND_STR}
    fc -p
}

It's been quite a struggle getting this to work right (eg using print -S so it won't screw up !$ et. al.), but it's mostly working right for me now.

However I am noticing some slight inconsistencies in what gets saved now that I am building a python script that pretty-prints the saved commands in colored columns.

To illustrate:

% echo "\\"
\

now the ~/.zsh_enhanced_history now contains:

/home/slu/util; echo "\"; /dev/pts/20@1376064693.136746657

So, it saves echo "\\\\" (which produces the output \\ ) as echo "\\" (which is not a well-formed command).

Similarly, the command echo "\\n" is saved in with a literal newline so it will take up two lines in the history file. It is in fact this behavior that caused me to initially find it because my python regex would produce as many failed parses for a command as that command has newlines in it.

I tried changing it so I save the output of printf "%q" "$COMMAND_STR" as $COMMAND_STR , and this does seem to tackle the newlines and maybe even the backslashes, but it makes it escape spaces and double-quotes, so it is also wrong.

The regular ~/.zsh_history file does not suffer from this issue, it contains the command exactly as it was typed.

So somewhere in my zshaddhistory I am not doing the right transformations. Perhaps there is an extra shell-string-eval occurring I need to prevent.

Need some help from the zsh experts out there!!

Answer 1

This example from the zsh mailing list uses print . Combining it with your function gives this:

zshaddhistory () {
    # Print to the default history file with the newline stripped. 
    print -sr -- "${1%%$'\n'}"

    # Ignore common commands. 
    COMMAND_STR=${1%%$'\n'}
    [[ ( -z $COMMAND_STR ) || ( $COMMAND_STR =~ hist(ory)? ) || \
        ( $COMMAND_STR =~ ^l(s\|l\|a)?$ ) || \
        ( $COMMAND_STR =~ ^(d\|gd\|git\ diff\|glp\|gg)$ ) \
        ]] && return 1


    # Switch history contexts
    fc -p ~/.zsh_history_detail
    # Push the current line into the current history context with newline stripped and user / time appended. 
    print -sr -- "${1%%$'\n'} ### ${PWD} $(date '+%Y-%m-%d %R')"
    return 1
}

This appears to do what you want. I've tested using echo "\\\\" and echo "\\n" :

charizard% cat ~/.zsh_history_detail                               
cat: /Users/simont/.zsh_history_detail: No such file or directory
charizard% echo "\\"                                               
\
charizard% cat ~/.zsh_history_detail                               
: 1376117319:0;echo "\\" ### /Users/simont 2013-08-10 16:18
charizard% cat "\n"      # This was an oopsie                      
cat: \n: No such file or directory
charizard% echo "\n"                                               


charizard% echo "\\"                                               
\
charizard% cat ~/.zsh_history_detail                               
: 1376117319:0;echo "\\" ### /Users/simont 2013-08-10 16:18
: 1376117334:0;cat "\n" ### /Users/simont 2013-08-10 16:18
: 1376117339:0;echo "\n" ### /Users/simont 2013-08-10 16:18
: 1376117343:0;echo "\\" ### /Users/simont 2013-08-10 16:19

I don't know what you mean by:

but it makes it escape spaces and double-quotes, so it is also wrong

so I can't test for that.

Answer 2

I got to the root of the problem, which is made evident by reading the zsh manpage section just a little more carefully than I did before.

Under print :

          -r     Ignore the escape conventions of echo.

So, the only change I had to make to my zshrc (my ~/.zshrc is symlinked to this zshrc file) was:

diff --git a/zshrc b/zshrc
index 5e72133..af97c35 100644
--- a/zshrc
+++ b/zshrc
@@ -68,7 +68,7 @@ function zshaddhistory() {
     # do not do anything on common commands

     # do the needful
-    echo "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history
+    print -r "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history

     # rest is "default" zshaddhistory()
     print -Sr ${COMMAND_STR}