DIR命令的输出与批处理文件中的预期不符

Question

I have a large collection of television series sitting on a NAS box, that shares media via samba and dlna throughout my home. To enable a random feature, I created a batch script as follows to make a playlist file:

    @Echo Off
    color 0e
    Echo PLEASE WAIT, BUILDING PLAYLIST FILE, EXCLUDING ALL BAT, TXT, M3U, SRT and JPG FILES
    del "playlist.m3u"
    Setlocal EnableDelayedExpansion
    set _tmp=%1
    Set _t0=1
    If ["%CD%"]==["%CD:~0,3%"] Set _t0=0
    For /F "tokens=*" %%A In ('Dir "%*" /a-d /b /on /s ^|find /v ".bat"^|  find /v ".m3u"^|find /v ".txt"^| find /v ".srt"^|find /v ".jpg"') Do (
   Set _t1=%%A
   Set _t2=!_t1:%CD%=!
   Echo !_t2:~%_t0%!)>>playlist.m3u

So, I have one of these batch files in each directory (one per TV show) as well as the parent folder (TV) and my users can enable random in WMP, VLC or w/e player they like, and just click the playlist to watch random anything, or more specifically a random episode of a specific show.

So, on to my question: why is my piped output not alphabetical? I really want to accomplish this in MS-DOS / CMD as programming is not my expertise, and this is pretty much the limit of my capability with scripting or anything else. I imagine the FIND command could be used more elegantly to filter out specific file types, and I suspect therein lies my issues with trying to sort the output. Even the show-specific playlists appear to have a random sort order (files within seasons are alphabetical, but the season order appears random) I was also wondering if someone could shed some light on getting folders with "&" in the name not breaking the output procedure.

Any help would be appreciated.

-TJ

Answer 1

Hmm..

First point - why do you need alphabetical order if your intention is to do some variety of "random" selection?

Next - why are you setting _tmp - you aren't using it.
Next - the brackets in your IF "%CD%"... are redundant - the quotes are there to tell batch that the string may contain separators
Next - the /on switch tells DIR to output the SELECTED directory in alphabetical order.
Next - _t0 appears to be intended to select 'lop 0' or 'lop 1' characters, but a DIR /s /b output will be X:\\dir...\\filename - doesn't sem particularly sensible...
Next - you seem to have omitted the /i switch from your FIND commands to make the find case-insensitive.

You've not shown your directory structure, so "season order" is nebulous. Presumably you've got ..\\showname\\season\\episode. Consider what happens when you have season 1,2..10,11. If sorted, you'd get 1,10,11,2.. Same comment may apply to your episode name.

Here's a method of producing a sorted list. In this case, it'll detect files containing with in all subdirectories from the current, minus the selected extensions in any case - because I have a reasonable number of filenames containing with and & (also ! and % ) in my batch-test directory. Note also that a new file is created without the delete and append method. also the output filename is different - and DELAYEDEXPANSION is not invoked.

@ECHO OFF
SETLOCAL 
(
 For /F "tokens=*" %%A In ('Dir "*with*" /a-d /b /s ^|find /i /v ".bat"^|  find /i /v ".m3u"^|find /i /v ".txt"^| find /i /v ".srt"^|find /i /v ".jpg"^|sort') Do (
ECHO %%A
 )
)>newfile.txt
GOTO :EOF

You don't say where the & is breaking your code. This structure doesn't care - the & and other difficult characters act quite happily. Perhaps your difficulies are with the code section you have shown - perhaps they are later on...

Finally, DIR is relatively simple and doesn't allow exclusion-by-name. Possibly a more elegant method would be by using

xcopy /y /L /s sourcedir x:\nul\

a matter for experimentation. XCOPY /? from the prompt for documentation - which will show how to use the /exclude: switch. Two cautions though - the xcopy approach will select directory names and the last line will be a count-of-files-in-list.

 if not exist "%%A\." if exist "%%A" ECHO %%A

should overcome these two problems.

Answer 2

See if this does what you need. Give an example playlist if it needs tweaking.

@Echo Off
color 0e
Echo PLEASE WAIT, BUILDING PLAYLIST FILE, EXCLUDING ALL BAT, TXT, M3U, SRT and JPG FILES
del "playlist.m3u" 2>nul
For /F "delims=" %%A In (' Dir "%*" /a-d /b /on /s ^|findstr /v /i ".bat .m3u .txt .srt .jpg" ^|sort ') Do (
Echo %%~pnxA
>>playlist.m3u Echo %%~pnxA
)

Answer 3

I know it's been a while, but here is the final batch script that generates my desired output:

@Echo Off
color 0e
Echo PLEASE WAIT, BUILDING PLAYLIST FILE, EXCLUDING BAT, TXT, M3U, SRT and JPG FILES
del "playlist.m3u"
Setlocal EnableDelayedExpansion
Set _t0=1
If ["%CD%"]==["%CD:~0,3%"] Set _t0=0
For /F "tokens=*" %%A In ('Dir "%*" /a-d /b /on /s ^|findstr /v /i ".bat .m3u .txt .srt .jpg"^| sort') Do (
Set _t1=%%A
Set _t2=!_t1:%CD%=!
Echo !_t2:~%_t0%!)>>playlist.m3u

I'm sorry I took so long to get back here, but you know, life gets in the way sometimes. Please find below a sample of my desired output. A file list in this manner works as a .m3u playlists that will play off of a network location whether the folder is mapped to a drive letter or not. It also works regardless of where in the folder hierarchy a user decides to map. Example:

Z:\md0\media\tv\30 rock\season 1\s01e01.avi
or
y:\tv\30 rock...
or
r:\30 rock...
or even
\\tjmediaserver\video\tv\30 rock\...

are all valid ways for users to access my open network share at this location. Sample batch output:

Season 1\30 Rock S01E01 Pilot.avi
Season 1\30 Rock S01E02 The Aftermath.avi
Season 1\30 Rock S01E03 Blind Date.avi

Both Windows Media Player and VLC (only players we use) assume the files are within the subdirectories of where the .m3u is stored. Handy if I want to watch show "X" from the beginning, or enable shuffle in my media player and watch random "x" or random "x" and "y".