如何在Perl中正则表达式0或数字

Question

I'm tryin to capture the follwoing from the below lines in my file:

1.39223 0.303787
71.9792 0

Input file (example):

XLOC_000559 XLOC_000559 -   S3603:13352-18211   con exp OK  1.39223 0.303787    -2.19627    -1.93877    0.0001  0.0140909   yes
XLOC_001511 XLOC_001511 -   S7778:1319-1421 con exp OK  71.9792 0   -inf    -nan    0.00035 0.0365407   yes

I've tried the regex:

my ($con_val, $expt_val) = ($1, $2) if ($_ =~ /OK\t(\d+\.\d+)\t(\d+\.\d+)/);

But its not working on 0 values...

Can anyone help please?

Answer 1

There is almost certainly no need to make sure your numbers contain a maximum of one decimal point, and the easiest way to solve this is to use a character class [\\d.] that matches any digit or a dot.

Note that a regex will be applied to $_ unless you say otherwise, so there is no need to write $_ =~ .

This short program should help you.

use strict;
use warnings;

while (<DATA>) {
  next unless /OK\s+([\d.]+)\s+([\d.]+)/;
  my ($con_val, $expt_val) = ($1, $2);
  print "$con_val, $expt_val\n";
}

__DATA__
XLOC_000559 XLOC_000559 -   S3603:13352-18211   con exp OK  1.39223 0.303787    -2.19627    -1.93877    0.0001  0.0140909   yes
XLOC_001511 XLOC_001511 -   S7778:1319-1421 con exp OK  71.9792 0   -inf    -nan    0.00035 0.0365407   yes

output

1.39223, 0.303787
71.9792, 0

Answer 2

You have to make the \\.\\d+ optional by wrapping it in parentheses with a ? :

/OK\t(\d+(?:\.\d+)?)\t(\d+(?:\.\d+)?)/

The ?: after the open-paren prevents the regex engine from creating a grouping in the match result.

Answer 3

use Regexp::Common;
my ($con_val, $expt_val) = /OK\s+ ($RE{num}{real}) \s+ ($RE{num}{real})/x;

or

perl -anE 'say "@F[7,8]"' file

Answer 4

假设第二个值（您要捕获为“ $ expt_val”）后面总是接一个制表符，那么这应该可以工作：

my ($con_val, $expt_val) = ($1, $2) if ($row =~ /OK\t(\d+\.\d+)\t(.+)\t/);

Answer 5

You should use the or operator | to specify either:

• One or more digits (\\d+) followed by a literal . (\\.) followed by one or more digits (\\d+)

OR

• A literal 0

Try this:

#!/usr/bin/perl
use warnings;
use strict; 
use Data::Dumper;

my @array =('XLOC_000559    XLOC_000559 -   S3603:13352-18211   con exp OK  1.39223 0.303787    -2.19627    -1.93877    0.0001  0.0140909   yes',
    'XLOC_001511    XLOC_001511 -   S7778:1319-1421 con exp OK  71.9792 0   -inf    -nan    0.00035 0.0365407   yes');

foreach (@array){
    my ($con_val, $expt_val) = ($1, $2) if ($_ =~ /OK\t(\d+\.\d+|0)\t(\d+\.\d+|0)/); 
    print "$con_val\t$expt_val\n";
}

Outputs:

1.39223 0.303787
71.9792 0

Or better yet, assuming your values are separated by a \\t , I'd go for this:

my (@con_val, @expt_val);
foreach (@array){
    my @split = split(/\t/);
    push @con_val, $split[7];
    push @expt_val, $split[8];
}

print Dumper \@expt_val;
print Dumper \@con_val;

Outputs:

$VAR1 = [
          '0.303787',
          '0'
        ];
$VAR1 = [
          '1.39223',
          '71.9792'
        ];