AS2-使用预加载器加载外部SWF文件后，我无法控制它

Question

I have made an educational tool for a project and now it's time to put it online. It's about 12 Mb in size, so I thought a preloader would be a great idea. I found this nice external preloader which shows progress bar, percentage and loads the main swf, but then I have no control over the main swf. Everything on it appears as an MC without any code (mouse cursor changes to that hand showing a finger :) ) and, thus, does not respond to input. Does anyone know how to fix it? The code of the preloader:

import flash.geom.*
import flash.display.*

var loadurl:String = "project.swf";
var nDepth:Number = 0;
var nWidth:Number = 200;
var nHeight:Number = 20;
var nPadding:Number = 3;
var cLoader:MovieClipLoader = new MovieClipLoader();
var oListener:Object = {onLoadInit:onContentLoaded};
var mcLoader:MovieClip = this.createEmptyMovieClip("Loader_MC", 0);
var mcContent:MovieClip = this.createEmptyMovieClip("Content_MC", 1);
var mcLoadBarBg:MovieClip = mcLoader.createEmptyMovieClip("LoadBarBg_MC", nDepth++);
var mcLoadBar:MovieClip = null; //Duplicated later with mcLoadBarBg 
var txtPercLoad:TextField = null; //Create after duplication
var cMatrix:Matrix = new Matrix();
mcLoader._alpha = 0;
cMatrix.createGradientBox(nWidth, nHeight, 0, nPadding, nPadding);
cLoader.addListener(oListener);
mcLoader.lineStyle(1, 0x000066, 100);
DrawRect(mcLoader, 0, 0, nWidth, nHeight);
mcLoadBarBg.lineStyle(1, 0x0000FF, 0);
mcLoadBarBg.beginGradientFill("linear", [0x006699, 0x0066FF], [100,100], [0, 255], cMatrix, SpreadMethod.PAD);
DrawRect(mcLoadBarBg, 0, 0, nWidth - nPadding*2, nHeight - nPadding*2);
mcLoadBarBg.endFill();
mcLoadBar = mcLoadBarBg.duplicateMovieClip("LoadBar_MC", nDepth++);
txtPercLoad = mcLoader.createTextField("PercLoad_TXT", nDepth++, 0, 0, nWidth, nHeight);
mcLoadBar._alpha = 80;
mcLoadBarBg._alpha = 30;
Translate(mcTextMask, nPadding, nPadding);
Translate(mcLoadBarBg, nPadding, nPadding);
Translate(mcLoadBar, nPadding, nPadding);
mcLoadBar._xscale = 0;
mcContent._alpha = 0;
mcContent._lockroot = true;
mcLoader._x = Stage.width/2 - mcLoader._width/2;
mcLoader._y = Stage.height/2 - mcLoader._height/2;
txtPercLoad._x = mcLoader._width/2 - txtPercLoad._width/2;
txtPercLoad._y = mcLoader._height/2 - txtPercLoad._height/2;
SetTextFormat(txtPercLoad, "0%");
mcLoader._alpha = 100;
cLoader.loadClip(loadurl, mcContent);

_root.onEnterFrame = function()
{
   var nBytesLoaded:Number = mcContent.getBytesLoaded();
   var nBytesTotal:Number = mcContent.getBytesTotal();
   var nPercLoaded:Number = Math.round(nBytesLoaded / nBytesTotal * 100);
   if(nPercLoaded > 0)
   {
      SetTextFormat(txtPercLoad, nPercLoaded.toString() + "%");
      mcLoadBar._xscale = nPercLoaded;
   }
}

function onContentLoaded(Void):Void
{
   //trace(_root + "::onContentLoaded");
   SetTextFormat(txtPercLoad, "100%");
   cLoader.removeListener(oListener);
   delete _root.onEnterFrame;
   delete oListener;
   delete cLoader;
   _root.onEnterFrame = function()
   {
      //trace(_root + "::onContentLoaded::_root.onEnterFrame");
      var nInc:Number = 5;
      mcLoader._alpha -= nInc;
      mcContent._alpha += nInc;
      if(mcLoader._alpha <= 0) startLoadedContent();
   }
}

function startLoadedContent(Void):Void
{
   delete _root.onEnterFrame;
   mcLoader.removeMovieClip();
   mcContent._alpha = 100;
}

function DrawRect(mc:MovieClip, nX:Number, nY:Number, nW:Number, nH:Number, nR:Number)
{
   //trace("DrawRect in: " + mc);
   if(nR == undefined) nR = 6;
   mc.moveTo(nX+nR,nY);
   mc.lineTo(nX+nW-nR,nY);
   mc.curveTo(nX+nW,nY,nX+nW,nY+nR);
   mc.lineTo(nX+nW,nY+nH-nR);
   mc.curveTo(nX+nW,nY+nH,nX+nW-nR,nY+nH);
   mc.lineTo(nX+nR,nY+nH);
   mc.curveTo(nX,nY+nH,nX,nY+nH-nR);
   mc.lineTo(nX,nY+nR);
   mc.curveTo(nX,nY,nX+nR,nY);
}

function SetTextFormat(txtField:TextField, sText:String)
{
   var txtFmt:TextFormat = new TextFormat();
   sText = "Loading... " + sText;
   txtFmt.font = "Verdana";
   txtFmt.align = "center";
   txtFmt.size = 11;
   txtFmt.color = 0x000066;
   txtFmt.bold = true;
   txtField.selectable = false;
   txtField.text = sText;
   txtField.setTextFormat(txtFmt);
   txtFmt = null;
}

function Translate(mc:MovieClip, nX:Number, nY:Number):Void
{
   mc._x = nX;
   mc._y = nY;
}

EDIT: To better visualise the problem, I uploaded what I have. This is the version without preloader (give it some time to load): Without preloader . And this is what happens to the main program with preloader: With preloader

Answer 1

The code you attached works perfectly well. It can't interfere with you loaded file in any kinds. I bet your problem is that your scripts in original file wrote using absolute path to objects (with _root and stuff). But when you load your original swf in new one with this loader, the new hierarchy appears. All you objects now inside MovieClip named mcContent . And you should consider that in you scripts inside main file. Otherwise you could use _lockroot property. In first frame of your main project file write:

this._lockroot = true;

Now, even if this swf file will be loaded inside other one, all _root calls from it will target it own top level. I might solve your problem. If its not, please add some code samples from buttons and stuff from your loaded file.

Now I am sure that problem is in that roots. Use should use relative keywords to access your object. Change your button code to at to

on(release){
    this.help = true;
    this.gotoAndStop("mainVideo");
}

It should help. If it not when there can be few reasons for this.

1. Instance on which code ( on(release){...} ) was written is not on main timeline. If it is inside another object (MovieClip, for example) then relative path in code should be other.
2. The instance on which code was written is not instance of Button , but instance of MovieClip . In that case, using the on(...) handler on it - is kind of acceptable hack.

There is differences in use of this . Keyword this used inside on(...) of Button instance lead you to the object where instance a placed. If this button lay somewhere in main timeline in any frame then this return id of main timeline. If you use this inside on(...) of MovieClip then it return id of this MovieClip .

To determine exactly where the objects are and how you could refer from they location to object you need you should use trace(...); method.

Inside your button code add

trace(this);
trace(_root);

After that make preview of your main swf from Flash Professional ( Ctrl + Enter ) Press your button. In output window you will get references to this and _root relatively to your code. Save it somewhere. Then open your loader project and make preview of it. I should load you main swf with you button inside. Press it. Look at output. Save it. Now you could compare trace results to determine changes between main file standalone and loaded inside your loader swf.

In first trace you will get something like this

_level0.someInstanceName
_level0

In second

_level0.mcContent.someInstanceName
_level0

This references will help to call right objects. As you see, this and _root lead to different places. For us part of address before help variable and gotoAndStop() methods should lead to the top level object of your main swf. Top level which we want access to in first trace is _level0 . In second trace as I said earlier '_level0.mcContent'. And now you see why we can't use _root . It will guide us to the topmost object in both cases. But now we see place of 'this' in hierarchy. It stay the same (even if reference to it object looks longer we still see same object in trace results of this ); And we see how deep inside our this relatively to our top object in main swf (first trace result). It is first level after _root . So all we need now is to climb up the hierarchy. And for this we should use _parent keyword. If we want climb up form _level0.someInstanceName to _level0 we will use

this._parent

So if you outputs is similar to what I guess you code for your button should look like

on(release){
    this._parent.help = true;
    this._parent.gotoAndStop("mainVideo");
}

As you may guess this._parent when it used inside loaded swf will lead to same right object _level0.mcContent and code will work right as you suspect it should.