使用controlpopup vba运行宏

Question

I am trying to write a macro that will create a popup window that will allow me to navigate between pages of a workbook. So far I have been able to populate a controlpopup that runs a simple macro, but I would like it to be able to accept variables (aka the sheetname) to avoid having to write a bunch of different macros. Here is what I have so far.

Sub Custom_PopUpMenu_1(Mname As String)
    Dim MenuItem As CommandBarPopup
    ' Add the popup menu.
    With Application.CommandBars.Add(Name:=Mname, Position:=msoBarPopup, _
         MenuBar:=False, Temporary:=True)

        With .Controls.Add(Type:=msoControlPopup)
            .Caption = "Menu Control"
              With .Controls.Add(Type:=msoControlButton)
                .Caption = "Button 1 in menu"
                .FaceId = 71
                .OnAction = "'" & ThisWorkbook.Name & "'!" & "TestMacro"
            End With
        End With 
    End With
End Sub

This runs the macro 'TestMacro' but am not sure how to write it so that it will accept a string variable. My other though is that in each .OnAction to update a global variable that is the sheetname, but am unsure of how to do that either. Let me know if you can help out. Thanks!

Answer 1

Your testmacro should launch a userform which would have a ComboBox and a CommandButton

The logic is, when the userform initializes, it will store all the sheet names from the current workbook in the ComboBox and you can use the CommandButton to navigate to that sheet.

Here is an Example

Private Sub UserForm_Initialize()
    Dim ws As Worksheet

    For Each ws In ActiveWorkbook.Worksheets
        ComboBox1.AddItem ws.Name
    Next ws
End Sub

Private Sub CommandButton1_Click()
    Dim wsName As String

    If ComboBox1.ListIndex <> -1 Then
        wsName = ComboBox1.List(ComboBox1.ListIndex)

        If ActiveWorkbook.Sheets(wsName).Visible <> xlSheetVisible Then
            ActiveWorkbook.Sheets(wsName).Visible = True
        End If

        ActiveWorkbook.Sheets(wsName).Activate
    End If
End Sub

ScreenShot

Answer 2

This should work (at least, it works for a shape on a worksheet)

.OnAction = "'" & ThisWorkbook.Name & "'!'TestMacro ""blah22""'"

...but if what you want is to navigate to a particular sheet then right-clicking on the "VCR" control to the left of the sheet tabs is the easiest built-in way...

If your parameter is in a variable you can do this:

.OnAction = "'" & ThisWorkbook.Name & "'!'TestMacro """ & stringvariable  & """'"