VBA For循环将单元格从Excel复制到Word

Question

I'm trying to create an excel macro to copy cells from excel to word. I need to take it from sheet 1 in excel to table 1 in word.

I need to do this via a loop (as I have to perform operations on the cells etc.) and I can't work out how to do it. I have the following code:

Sub test()

Dim wdDoc As Object
Dim FileName As String
Dim iRow As Integer
Dim iCol As Integer

'Open Word file
FileName = ActiveWorkbook.Path & "\Template.doc"
Set wdApp = New Word.Application
Set wdDoc = wdApp.Documents.Open(FileName)



' Loop through columns and rows
For iCol = 1 To 3 ' or however many columns you have
    For iRow = 1 To 2

    With Worksheets("Sheet1").Cells(iRow, iCol)
        ' Copy the cell to the destination
        .Copy
        wdDoc.Selection.Paste
    End With

    Next iRow
Next iCol

End Sub

When I run this though, the line wdDoc.Selection.Paste gives the error:

Run-time error '438': Object does not support this property or method.

I'm also aware that this doesn't paste into table 1 of the document, but right now it doesn't do anything , so I thought I'd work on that first. I'm new to VBA but have other programming experience. Can someone please help me?

Answer 1

This should work:

wdApp.Selection.Range.Paste

EDIT : more complete example

Sub test()

Dim wdDoc As Word.Document, wdApp As Word.Application
Dim tbl As Word.Table


Dim FileName As String
Dim iRow As Integer
Dim iCol As Integer


    FileName = "C:\_stuff\Local Files\temp.docx"
    Set wdApp = New Word.Application

    wdApp.Visible = True 'add this to see the Word instance and document

    Set wdDoc = wdApp.Documents.Open(FileName)

    Set tbl = wdDoc.Tables(1)

    ' Loop through columns and rows
    For iRow = 1 To 2
    For iCol = 1 To 3 ' or however many columns you have
        With Worksheets("Sheet1").Cells(iRow, iCol)
            tbl.Rows(iRow).Cells(iCol).Range.Text = .Value
        End With
    Next iCol
    Next iRow


    wdDoc.Close False  ' close doc and save changes
    wdApp.Quit        'close word (will auto-close if no open documents)

End Sub