在多维中搜索一维数组。 数组

Question

Please what would be the fastest (and most 'elegant') way to search for FaDirection array in the multi dim. FdVSubs array?

TaDirection = array[0..7] of TSubRect; //TSubRect = class(TObject)

Multi dim array:
FdVSubs: array[0..15] of TaDirection;

Array:
FaDirection : TaDirection;

I need to resolve if FaDirection is already stored in FdVSubs or not.

Thank You.

Answer 1

First and most important, you need to decide what defines two arrays as being equal. Then you'll have to adjust my code to match that definition. For the answer I'll assume arrays are equal if and only if they have identical object references at each corresponding position in the arrays.

function DirectionsAreEqual(const ADirection1, ADirection2: TaDirection): Boolean;
var
  LoopI: Integer;
begin
  Result := True;
  for LoopI := Low(TaDirection) to High(TaDirection) do
  begin
    if (ADirection1[LoopI] <> ADirection2[LoopI]) then
    begin
      Result := False;
      Exit;
    end;
  end;
end;

function DirectionExistsIn(const ADirection: TaDirection;
    const ADirectionList: array of TaDirection): Boolean;
var
  LoopI: Integer;
begin
  Result := False; //Caters for empty DirectionList
  for LoopI := Low(ADirectionList) to High(ADirectionList) do
  begin
    Result := DirectionsAreEqual(ADirection, ADirectionList[LoopI]);
    if (Result) then
    begin
      Exit;
    end;
  end;
end;

//Then you can simply do the test as follows:
if DirectionExistsIn(FaDirection, FdVSubs) then ...

NOTES

• DirectionExistsIn uses an Open Array, so it doesn't matter how many elements are defined for the FdVSubs array.
• A small change to DirectionExistsIn can allow you to return the position of the duplicate.