我如何在XSLT中包含一个兄弟姐妹？

Question

I have xml like so that I cannot change

<entry>
    <sn>1 a</sn>
    <dt>:to run away often from danger or evil</dt>
    <sn>b</sn>
    <dt>:to hurry toward a place of security</dt>
    <sn>2</sn>
    <dt>:to pass away swiftly</dt>
</entry>

And i'm trying to write xslt to get it to look like this

    <div class="entry">
        <div class="def_group">
            <span class="def_group_number">1</span>
            <div class="def_value">
                 <span class="def_value_letter">a</span>
                 <span class="the_def">:to run away often from danger or evil</span>
            </div>

            <div class="def_value">
                 <span class="def_value_letter">b</span>
                 <span class="the_def">:to hurry toward a place of security</span>
            </div>
        </div>

        <div class="def_group">
            <span class="def_group_number">2</span>
            <div class="def_value">
                 <span class="the_def">:to pass away swiftly</span>
            </div>
        </div>
   </div>

When I break it down I have two questions really.

How, using XSLT 1.0, do I separate the three cases of < sn > ("letter", "number", "number letter") ?

And, in the cases containing a number, how do I write a template with a < div > that will contain its sibling < dt > as a child?

Answer 1

XSLT 1.0 isn't great for string manipulation, but I think this can be done. First off, we're going to need to find all the letter sn s that belong to a number one, so let's define a key for that

<xsl:key name="subsenseByMainSense"
   match="sn[not(number(substring(., 1, 1)) = number(substring(., 1, 1)))]"
   use="generate-id(preceding-sibling::sn[
           number(substring(., 1, 1)) = number(substring(., 1, 1))][1])" />

This looks weird but it's all idioms - the number() = number() is a way to check whether the thing in question (here the first character of the node's string value) is a number. If the thing you're checking is a number then the test is checking a number for equality to itself, which is always true; if it's not a number then the test is NaN = NaN which is always false.

Now starting from an entry you want one def_group for each sn that starts with a number:

<xsl:template match="entry">
  <div class="entry">
    <xsl:apply-templates select="sn[number(substring(., 1, 1))
                                  = number(substring(., 1, 1))]" />
  </div>
</xsl:template>

<xsl:template match="sn">
  <div class="def_group">
    <span class="def_group_number">
      <xsl:choose>
        <xsl:when test="contains(., ' ')">
          <xsl:value-of select="substring-before(., ' ')"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="." />
        </xsl:otherwise>
      </xsl:choose>
    </span>

    <!-- do the value(s) of this element and any following letter-only ones -->
    <xsl:apply-templates mode="value"
         select=". | key('subsenseByMainSense', generate-id())" />
  </div>
</xsl:template>

Now for the value bit, if this element has a letter then add a def_value_letter , otherwise just the the_def :

<xsl:template match="sn" mode="value">
  <xsl:variable name="letter"
     select="translate(., translate(., 'abcdefghijklmnopqrstuvwxyz', ''), '')" />
  <div class="def_value">
    <xsl:if test="$letter">
      <span class="def_value_letter">
        <xsl:value-of select="$letter" />
      </span>
    </xsl:if>
    <span class="the_def">
      <xsl:value-of select="following-sibling::dt[1]" />
    </span>
  </div>
</xsl:template>

The double-translate is another idiom - it's a way to remove all characters from a string except those in a specific "whitelist", so in this case to strip out all non-letter characters from the string.