Mac 上 excel 中的进度条

Question

I am using a progress bar in vba with excel but it will not display on my mac unless i step through, then it works fine. Any suggestions?

Sub Delete_duplicates()

    Dim x As Integer
    Dim LastRow As Long
    Dim xMax As Long
    Dim MyTimer As Double

    LastRow = Range("A65536").End(xlUp).Row
    xMax = LastRow

    For x = LastRow To 1 Step -1
        Application.StatusBar = "Progress: " & x & " of  " & Format(xMax)
        If Application.WorksheetFunction.CountIf(Range("A3:A" & x), Range("A" & x).Text) > 1 Then
            Range("A" & x).EntireRow.Delete

        End If
    Next x
Application.StatusBar = False


End Sub

Answer 1

If you add DoEvents to your loop, the status bar will update. Something like this:

   For x = LastRow To 1 Step -1
        Application.StatusBar = "Progress: " & x & " of  " & Format(xMax)
        DoEvents ' <<<<<<< new line
        If Application.WorksheetFunction.CountIf(Range("A3:A" & x), Range("A" & x).Text) > 1 Then
            Range("A" & x).EntireRow.Delete  
        End If
    Next x

You might consider not doing this on every row - for example you could have a line

If Mod(x, 10) = 0 Then DoEvents

to make the updating less frequent. Experiment a bit until you get the result you want.

Source: http://www.ozgrid.com/forum/showthread.php?t=160203

Answer 2

I don't have the reputation points yet to make the comment, but I thought I should point out that @Floris' suggestion:

    If Mod(x, 10) = 0 Then DoEvents

only works as a worksheet function. In order to use Mod in VBA, you need to use the following syntax:

    If x Mod 10 = 0 Then DoEvents

At least, that's how it needs to work on Excel for Mac 2011, on my computer.