使用Perl计算文本文件中的唯一项

Question

I have a text file with thousands of names listed First Name | Last Name. Any examples on how to use Perl to count only the unique last names?

I am already doing a standard count using $count++ to get the grand total, but I still need to know a unique count.

Thanks for any suggestions!

Answer 1

The standard approach is to use a hash (associative array) whose keys are the strings you want to count. Since a hash only includes a given key at most once, this lets you count distinct strings. For example:

my @input_list = ('a', 'b', 'a', 'b', 'a');
my %result_hash;
foreach my $val (@input_list) {
    ++$result_hash{$val};
}
# %result_hash is now (a => 3, b => 2)
print scalar keys %result_hash; # prints '2' (the number of keys)

Answer 2

Because keys of a hash are always unique, I suggest that you can make elements, which should be unique in a set, the keys of a hash. In your case, using a hash that have last names as keys to remove repetitive ones and to count the number of people that have each last name.

$nameList=['Eric|Johnson',
            'Herbert|Schildt',
            'Carl|Schildt',
            'Rose|Johnson',
            'Allen|Johnson',];
$nameHash={};
map {$_=~/\|(\w+)/; $nameHash->{$1}+=1;} @{$nameList};
# read the string behind "|"
# subsequently, make this string the key of hash
# increase the value of this key to count the number of people having this last name
map {print "$_: $nameHash->{$_} people\n"} keys %{$nameHash};

Then, you can get the result like

Johnson: 3 people
Schildt: 2 people

All in all, recall hash anytime you want a set. Cheers!

Answer 3

Another way of doing it, hopefully a bit more readable:

#!/usr/bin/perl
use strict;
use warnings;

my %names = ();
while (  my $name = <DATA>)
{
     chomp($name);
     my ($fname, $lname) = split(/\|/, $name);
     if (exists($names{$lname}))
     {
       $names{$lname} += 1;
     }
     else
     {
       $names{$lname} = 1;
     }

}

foreach my $name (sort { $names{$b} <=> $names{$a} } keys %names) {
  printf "%s: %s\n", $name, $names{$name};
}

print "Unique Names: " . scalar keys(%names) . "\n";

__DATA__
Rosetta|Drayer
Celinda|Blaylock
Twana|Riner
Mike|Riner
Bob|Riner
Linda|Riner
Liliana|Littlejohn
John|Littlejohn
Candance|Candanoza
Brian|Candanoza
George|Candanoza
Noreen|Frandsen
Nakisha|Feltmann
Vanetta|Feltmann
Lorretta|Feltmann
Domenic|Feltmann
Madalene|Feltmann
Rosalinda|Feltmann
Brandie|Feltmann
Nu|Feltmann
Tennille|Feltmann

Output - sorted by number descending order

Feltmann: 9
Riner: 4
Candanoza: 3
Littlejohn: 2
Frandsen: 1
Drayer: 1
Blaylock: 1

Unique Names: 7

Answer 4

This is another way using the uniq function:

#!/usr/bin/perl
use strict;
use warnings;

use List::MoreUtils 'uniq';


my @names = ();
while (  my $name = <DATA>)
{
     chomp($name);
     my ($fname, $lname) = split(/\|/, $name);
     push(@names, $lname);
}

my @uniq = uniq @names;
print "Unique Names: " . scalar @uniq . "\n";

__DATA__
Rosetta|Drayer
Celinda|Blaylock
Twana|Riner
Mike|Riner
Bob|Riner
Linda|Riner
Liliana|Littlejohn
John|Littlejohn
Candance|Candanoza
Brian|Candanoza
George|Candanoza
Noreen|Frandsen
Nakisha|Feltmann
Vanetta|Feltmann
Lorretta|Feltmann
Domenic|Feltmann
Madalene|Feltmann
Rosalinda|Feltmann
Brandie|Feltmann
Nu|Feltmann
Tennille|Feltmann

Output

Unique Names: 7

Answer 5

Just use a hash to keep track of the values, and then count at the end:

perl -lne '
     my ($ln) = (split /\s*\|\s*/)[1];
     $h{$ln}++;
     END { print scalar keys %h }
  ' file.txt

Answer 6

What you want is a dictionary. You would read the lines, one by one (in a while loop, probably), remove newline characters, split by the pipe character, so you have a variable, say $lastname , which has the field you want.

Then, you do the following: $count{$lastname}++ .

Note that $count{$lastname} is completely unrelated to $count ; it is a separate variable.

Once your loop is complete, you can go through each lastname: foreach $lastname (keys(%count)) {... and print out $lastname and $count{$lastname} .