通过xslt将属性从一个xml文件移动到另一个

Question

So I have an XML file with the following format:

[...]
<level1>
    <para id="1"/>
    <image type="photo" artist="Joe"/>
    <para id="2"/>
    <para id="3"/>
    <level2>
        <para id="4"/>
        <image type="pencil" artist="Bob"/>
        <para id="5"/>
    </level2>
    <para id="6"/>
    <image type="oil" artist="Joe"/>
</level1>
[...]

The problem is that the image attributes aren't always right, and they don't have a unique identifier. I have another file that has all the correct attributes. I'm trying to write a transform that will remove the incorrect attributes, and then place the correct attributes from my other file.

Here's what I have so far:

<xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <!-- ============================================================= -->
    <xsl:variable name="target" select="document('correct.xml')//image"/>


    <xsl:template match="image">
        <xsl:variable name="vPath1">
            <xsl:for-each select="ancestor-or-self::*">
                <xsl:value-of select="concat('/',name())"/>
            </xsl:for-each>
        </xsl:variable>
        <xsl:variable name="vPath2">
            <xsl:for-each select="$target[ancestor-or-self::*]">
                <xsl:value-of select="concat('/',name())"/>
            </xsl:for-each>
        </xsl:variable>
        <xsl:copy>
            <xsl:if test="$vPath1=$vPath2">
                <xsl:copy-of select="$target/@*"/>
            </xsl:if>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

This successfully removes all of my incorrect attributes, but it doesn't place the correct ones. It seems like my 'if' statement is never hitting, but I know that the paths are the same. What did I do wrong?

my correct.xml looks like this (which is also what the output should look like):

[...]
<level1>
    <para id="1"/>
    <image type="pencil" artist="Joe"/>
    <para id="2"/>
    <para id="3"/>
    <level2>
        <para id="4"/>
        <image type="photo" artist="Steve"/>
        <para id="5"/>
    </level2>
    <para id="6"/>
    <image type="oil" artist="Bob"/>
</level1>
    [...] 

Answer 1

If the structure of the 2 XML docs match exactly, you can match the paths using positional predicates. This will ensure that you're comparing unique paths.

Otherwise you'll have to match on id's or something. If that's the case, let me know and I can update my answer to use the id (or whatever) attributes when generating the paths.

XML Input

<level1>
    <para id="1"/>
    <image type="photo" artist="Joe"/>
    <para id="2"/>
    <para id="3"/>
    <level2>
        <para id="4"/>
        <image type="pencil" artist="Bob"/>
        <para id="5"/>
    </level2>
    <para id="6"/>
    <image type="oil" artist="Joe"/>
</level1>

Correct XML (I named it so_good.xml.)

<level1>
    <para id="1"/>
    <image type="pencil" artist="Joe"/>
    <para id="2"/>
    <para id="3"/>
    <level2>
        <para id="4"/>
        <image type="photo" artist="Steve"/>
        <para id="5"/>
    </level2>
    <para id="6"/>
    <image type="oil" artist="Bob"/>
</level1>

XSLT 2.0 (also works as 1.0)

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="good" select="document('so_good.xml')"/>

    <xsl:template name="getPath">
        <xsl:for-each select="ancestor-or-self::*">
            <xsl:value-of select="concat('/',local-name())"/>
            <!--Predicate is only output when needed.-->
            <xsl:if test="(preceding-sibling::*|following-sibling::*)[local-name()=local-name(current())]">
                <xsl:value-of select="concat('[',count(preceding-sibling::*[local-name()=local-name(current())])+1,']')"/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="image">
        <xsl:variable name="currPath">
            <xsl:call-template name="getPath"/>
        </xsl:variable>
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:apply-templates select="$good//image" mode="new-attrs">
                <xsl:with-param name="currPath" select="$currPath"/>
            </xsl:apply-templates>
            <xsl:apply-templates select="node()"/>
        </xsl:copy>        
    </xsl:template>

    <xsl:template match="image" mode="new-attrs">
        <xsl:param name="currPath"/>
        <xsl:variable name="goodPath">
            <xsl:call-template name="getPath"/>
        </xsl:variable>
        <xsl:if test="$currPath=$goodPath">
            <xsl:copy-of select="@*"/>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

XML Output

<level1>
   <para id="1"/>
   <image type="pencil" artist="Joe"/>
   <para id="2"/>
   <para id="3"/>
   <level2>
      <para id="4"/>
      <image type="photo" artist="Steve"/>
      <para id="5"/>
   </level2>
   <para id="6"/>
   <image type="oil" artist="Bob"/>
</level1>

To help show what's being compared, you can add this xsl:message to the "new-attrs" moded "image" template:

<xsl:message>Comparing "<xsl:value-of select="$currPath"/>" (currPath) to "<xsl:value-of select="$goodPath"/>" (goodPath). Do they match? <xsl:value-of select="boolean($currPath=$goodPath)"/></xsl:message>

You should see messages like: (sorry for the image)