通过xslt从xml中删除错误的属性

Question

i have some xml and i am trying to remove bad attributes that some other xslt add them.

 <?xml version="1.0" encoding="UTF-8"?><MYXML xmlns="http://someURL/MYXML" xmlns:role="http://someURL/role"> <firstElement> <LANGUAGE>Spanish</LANGUAGE> <VOCABULARY>Spain</VOCABULARY> </firstElement> <External xmlns="" xmlns:myxml="http://someURL/MYXML"> <EXTARData/> <AnotherElementData> <AnotherElement xmlns="http://someURL/AnotherElement"/> </AnotherElementData> </External> </MYXML><!--checksum=A477829F524D170104E87187AD2869F5443DD079196B0EDCD5C6B9CFDD315232 version=1--> 

i would like to rid off the "xmlns="" xmlns:myxml="http://someURL/MYXML"" without success.

my expected results is:

 <?xml version="1.0" encoding="UTF-8"?><MYXML xmlns="http://someURL/MYXML" xmlns:role="http://someURL/role"> <firstElement> <LANGUAGE>Spanish</LANGUAGE> <VOCABULARY>Spain</VOCABULARY> </firstElement> <External > <EXTARData/> <AnotherElementData> <AnotherElement xmlns="http://someURL/AnotherElement"/> </AnotherElementData> </External> </MYXML><!--checksum=A477829F524D170104E87187AD2869F5443DD079196B0EDCD5C6B9CFDD315232 version=1--> 

could someone help me with it?

Answer 1

So you seem to want to transform the elements in no namespace to the namespace of the root element:

  <xsl:template match="*[namespace-uri() = '']">
      <xsl:element name="{local-name()}" namespace="{namespace-uri(/*)}">
          <xsl:apply-templates select="@* | node()"/>
      </xsl:element>
  </xsl:template>

That together with the identity transformation gives

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*[namespace-uri() = '']">
      <xsl:element name="{local-name()}" namespace="{namespace-uri(/*)}">
          <xsl:apply-templates select="@* | node()"/>
      </xsl:element>
  </xsl:template>

</xsl:stylesheet>

and results in https://xsltfiddle.liberty-development.net/eiZQaFX

<MYXML xmlns="http://someURL/MYXML" xmlns:role="http://someURL/role">
    <firstElement>
        <LANGUAGE>Spanish</LANGUAGE>
        <VOCABULARY>Spain</VOCABULARY>
    </firstElement>
    <External>
        <EXTARData />
        <AnotherElementData>
            <AnotherElement xmlns="http://someURL/AnotherElement" xmlns:myxml="http://someURL/MYXML" />
        </AnotherElementData>
    </External>
</MYXML><!--checksum=A477829F524D170104E87187AD2869F5443DD079196B0EDCD5C6B9CFDD315232 version=1-->

As you see, that is not quite the result you have shown as the identity transformation in XSLT 1 copies the namespace xmlns:myxml="http://someURL/MYXML" that was in scope for the AnotherElement .

That problem can be avoided easily with an XSLT 2 or 3 processor by using

see https://xsltfiddle.liberty-development.net/eiZQaFX/1 .

With an XSLT 1 processor you would need more effort to make sure the elements are copied without any namespaces:

  <xsl:template match="*[namespace-uri() = '']//*[namespace-uri() != '']">
      <xsl:element name="{name()}" namespace="{namespace-uri()}">
          <xsl:apply-templates select="@* | node()"/>
      </xsl:element>
  </xsl:template>

Complete example is

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*[namespace-uri() = '']">
      <xsl:element name="{local-name()}" namespace="{namespace-uri(/*)}">
          <xsl:apply-templates select="@* | node()"/>
      </xsl:element>
  </xsl:template>

  <xsl:template match="*[namespace-uri() = '']//*[namespace-uri() != '']">
      <xsl:element name="{name()}" namespace="{namespace-uri()}">
          <xsl:apply-templates select="@* | node()"/>
      </xsl:element>
  </xsl:template>

</xsl:stylesheet>

at https://xsltfiddle.liberty-development.net/eiZQaFX/2