如何通过其属性值更改元素/标签值？

Question

I have a XML code with a long list of tags, and I want to replace in every element "text" the words inside and tags by their respective "form" attribute value.

For example, here's 2 sentences from my XML file:

<messages>
    <text>
        <spelling form="Hello">Helo</spelling> I'll see you next <abrev form="week">wk</abrev> alright.
    </text>
    <text>
        <abrev form="Come on">cmon</abrev> get ready <spelling form="dude">dood</spelling>!
    </text>
</messages>

Here's the output I'm looking for:

Hello I'll see you next week alright.
Come on get ready dude!

Does anyone have an idea how to do this?

---

Here is what I have so far in my XSL file:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:for-each select="messages/text">

        <xsl:call-template name="parse">

            <!-- this selects all the tags inside "text" (I think...) -->
            <xsl:with-param name="a" select="./*"/>

        </xsl:call-template>

    </xsl:for-each>
</xsl:template>

Then, my function "parse":

<xsl:template name="parse">

    <!-- "a" is the text to parse -->
    <xsl:param name="a"/>

    <!-- return the value of "form" -->
    <xsl:value-of select="$a/@form"/>

</xsl:template>

Now, my function "parse" isn't complete. I don't know how to replace the misspelled words by their "form" value.

Thank you for your help!

Answer 1

Assuming you may have both <abrev> or <spelling> elements in your text (actually any one with a form attribute), and that your real XML is well-formed, this stylesheet can be used to replace the tagged text with the value in the form attribute:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:apply-templates  select="messages/text"/>
    </xsl:template>

    <xsl:template match="text/*[@form]">
        <xsl:value-of select="@form"/>
    </xsl:template>
</xsl:stylesheet>

If you apply it to this input:

<messages>
    <text>
        <spelling form="Hello">Helo</spelling> I'll see you next <abrev form="week">wk</abrev> alright.
    </text>
    <text>
        <spelling form="Come on">cmon</spelling> get ready <abrev form="dude">dood</abrev>!
    </text>
</messages>

You will get this as output:

    Hello I'll see you next week alright.

    Come on get ready dude!

Answer 2

You can start with a identity template and from there create templates for each element so that you can control their specific output. So for example, have the text element output its text along with running the templates for the spelling and abrev elements, which output its @form attribute.

So that would look like the below.

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="messages">
    <xsl:apply-templates/>
  </xsl:template>

  <xsl:template match="text">
    <xsl:apply-templates select="*|text()"/>
  </xsl:template>

  <xsl:template match="spelling">
    <xsl:value-of select="@form"/>
  </xsl:template>

  <xsl:template match="abrev">
    <xsl:value-of select="@form"/>
  </xsl:template>