如何使用VBScript从CSV读取引用字段

Question

In a sample.csv file, which has fixed number of columns, I have to extract a particular field value and store it in a variable using VBScript.

sample.csv

100,SN,100.SN,"100|SN|   435623|   serkasg|  15.32|
               100|SN|   435624|   serkasg|  15.353|
               100|SN|   437825|   serkasg|  15.353|"," 0 2345"
101,SN,100.SN,"100|SN|   435623|   serkasg|  15.32|
               100|SN|   435624|   serkasg|  15.353|
               100|SN|   437825|   serkasg|  15.353|"," 0 2346"

I want to parse the last two fields which are within double quotes and store them in two different array variables for each row.

Answer 1

You could try using an ADO connection

Option Explicit

dim ado: set ado = CreateObject("ADODB.Connection")
ado.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=c:\txtFilesFolder\;Extended Properties=""text;HDR=No;FMT=Delimited"";"
ado.open

dim recordSet: set recordSet = ado.Execute("SELECT * FROM [samples.csv]")

dim field3, field4

do until recordSet.EOF

    field3 = recordSet.Fields(3).Value
    field4 = recordSet.Fields(4).Value

    ' use your fields here

    recordSet.MoveNext
loop
recordSet.close
ado.close

You may have an issue if those fields are greater than 255 characters in length - if they are, they may return truncated. You also may have better luck with ODBC or ACE connection strings instead of the Jet one I've used here.

Answer 2

Since CSV's are comma-separated, you can use the Split() function to separate the fields into an array:

' Read a line from the CSV...
strLine = myCSV.ReadLine()

' Split by comma into an array...
a = Split(strLine, ",")

Since you have a static number of columns (5), the last field will always be a(4) and the second-to-last field will be a(3) .

Answer 3

Your CSV data seems to contain 2 embedded hard returns (CR, LF) per line. Then the first line ReadLine returns is:

100,SN,100.SN,"100|SN| 435623| serkasg| 15.32|

The solution below unwraps these lines before extracting the required fields.

Option Explicit

Const ForReading = 1
Const ForAppending = 8

Const TristateUseDefault = 2 ' Opens the file using the system default. 
Const TristateTrue = 1       ' Opens the file as Unicode. 
Const TristateFalse = 0      ' Opens the file as ASCII. 

Dim FSO, TextStream, Line, LineNo, Fields, Field4, Field5

ExtractFields "sample.csv"

Sub ExtractFields(FileName)
  Set FSO = CreateObject("Scripting.FileSystemObject")
  If FSO.FileExists(FileName) Then
    Line = ""
    LineNo = 0
    Set TextStream = FSO.OpenTextFile(FileName, ForReading, False, TristateFalse)
    Do While Not TextStream.AtEndOfStream
      Line = Line & TextStream.ReadLine()
      LineNo = LineNo + 1
      If LineNo mod 3 = 0 Then
        Fields = Split(Line, ",")
        Field4 = Fields(3)
        Field5 = Fields(4)
        MsgBox "Line " & LineNo / 3 & ": " & vbNewLine & vbNewLine _
          & "Field4: " & Field4 & vbNewLine & vbNewLine _
          & "Field5: " & Field5

        Line = ""
      End If
    Loop
    TextStream.Close()
  Else
    MsgBox "File " & FileName & " ... Not found"
  End If
End Sub

Answer 4

Here is an alternative solution that allows for single or multiline CSV records. It uses a regular expression which simplifies the logic for handling multiline records. This solution does not remove CRLF characters embedded in a record; I've left that as an exercise for you :)

Option Explicit

Const ForReading = 1
Const ForAppending = 8

Const TristateUseDefault = 2 ' Opens the file using the system default. 
Const TristateTrue = 1       ' Opens the file as Unicode. 
Const TristateFalse = 0      ' Opens the file as ASCII. 

Dim FSO, TextStream, Text, MyRegExp, MyMatches, MyMatch, Field4, Field5

ExtractFields "sample.csv"

Sub ExtractFields(FileName)
    Set FSO = CreateObject("Scripting.FileSystemObject")
    If FSO.FileExists(FileName) Then
        Set MyRegExp = New RegExp
        MyRegExp.Multiline = True
        MyRegExp.Global = True
        MyRegExp.Pattern = """([^""]+)"",""([^""]+)"""
        Set TextStream = FSO.OpenTextFile(FileName, ForReading, False, TristateFalse)
        Text = TextStream.ReadAll
        Set MyMatches = MyRegExp.Execute(Text)
        For Each MyMatch in MyMatches
            Field4 = SubMatches(0)
            Field5 = SubMatches(1)
            MsgBox "Field4: " & vbNewLine & Field4 & vbNewLine & vbNewLine _
                & "Field5: " & vbNewLine & Field5, 0, "Found Match"
        Next
        Set MyMatches = Nothing
        TextStream.Close()
    Else
        MsgBox "File " & FileName & " ... Not found"
    End If
End Sub