在Indy TCP中发送消息

Question

iam trying to send message like this

strMsg := Memo.Text;
Tclient.IOHandler.WriteLn(strMsg);

But how do i recive the text inside memo.text in server execute event?

Remy example is fine but how i do it with code like this

procedure TChatFo.SendClick(Sender: TObject);
var
  strMsg: string;
begin
if tmemo.Text = '' then Abort;
strMsg := tmemo.Text;
Tcli.IOHandler.WriteLn(strMsg);
usertype.Clear;
end;

Answer 1

Indy servers are multi-threaded. Data is received in a worker thread, not the main UI thread. Once you have read the incoming message data (using AContext.Connection.IOHandler.ReadLn , for instance), you must then synchronize with the main thread if you want to display the message in a UI component. You can use Indy's TIdSync or TIdNotify class for that synching, or use the anonymous procedure overloads of TThread.Synchronize() or TThread.Notify() if your version of Delphi has them available.

For example:

uses
  ..., IdSync;

type
  TMemoSync = class(TIdSync)
  protected
    FText: string;
    procedure DoSynchronize; override;
  end;

procedure TMemoSync.DoSynchronize;
begin
  Form1.Memo1.Lines.Add(FText);
end;

procedure TForm1.IdTCPServer1Execute(AContext: TIdContext);
var
  Text: String;
begin
  Text := AContext.Connection.IOHandler.ReadLn; 

  with TMemoSync.Create do
  try
    FText := Text;
    Synchronize;
  finally
    Free;
  end;
end;

Or:

procedure TForm1.IdTCPServer1Execute(AContext: TIdContext);
var
  Text: String;
begin
  Text := AContext.Connection.IOHandler.ReadLn; 
  TThread.Synchronize(nil,
    procedure
      Form1.Memo1.Lines.Add(Text);
    end
  );
end;