如何将Windows批处理文件转换为签名行“ cmd / c”命令？

Question

I have the batch file below and wish to convert it to a single line cmd /c command.

@ECHO OFF
SETLOCAL
FOR /F "TOKENS=2 DELIMS=:." %%I IN ('chcp') DO SET _codepage_=%%I
SET _codepage_=Cp%_codepage_: =%
ECHO %_codepage_%
ENDLOCAL

I tried:

cmd /c FOR /F "TOKENS=2 DELIMS=:." %I IN ('chcp') DO @SET _codepage_=%I && @SET _codepage_=Cp%_codepage_: =% && @ECHO %_codepage_%

also tried:

cmd /v:on /c FOR /F "TOKENS=2 DELIMS=:." %I IN ('chcp') DO @SET _codepage_=%I && @SET _codepage_=Cp%_codepage_: =% && @ECHO !_codepage_!

but neither approach works! Can anyone help me out here?

Answer 1

cmd /q/c"for /f "tokens=2delims=:." %a in ('chcp')do for %b in (%a)do echo(Cp%b"

What did the original code do? split the output of chcp , remove the ending dot (I didn't knew it, thank you), storing the value inside a variable to remove a space from it and prefix it with Cp and then echo the variable

What does this code do? split the output of chcp , remove the ending dot, but instead of using a variable to remove the space, an aditional for loop is used over the value from the first loop, and, instead of prefixing the variable, the Cp is included in the data echoed.

Answer 2

I would use the MC ND answer . But just for yucks, I created another solution.

cmd /v:on /q /c "(for /f "delims=." %a in ('chcp') do for %b in (%a) do set cp=Cp%b) & echo !cp!"

Note that for all solutions, you might consider adding the /D option to prevent autorun commands from running.

Answer 3

It seems I was missing double quotes around the cmd command. This is how I finally did this:

cmd /v:on /q /c "FOR /F "TOKENS=2 DELIMS=:." %I IN ('chcp') DO SET _codepage_=%I && SET _codepage_=Cp!_codepage_: =! && ECHO !_codepage_!"

also correct as MC ND pointed out above:

cmd /q /c "FOR /F "TOKENS=2 DELIMS=:." %a IN ('chcp') DO FOR %b IN (%a) DO ECHO Cp%b"

I use this single command in Java with a ProcessBuilder in order to get the console's codepage and pass it to the process's stdout and stderr streams like this:

String encoding = getConsoleEncoding(); // use the above cmd command
BufferedReader stdout = new BufferedReader( new InputStreamReader(p.getErrorStream(),encoding) );

So the result of system commands like eg date /t will display correctly in Java.

Answer 4

You can save above into a file, name it as my.bat. Then use:

cmd.exe /c "call my.bat"

For In one command line, not use batch file, you can:

FOR /F "TOKENS=2 DELIMS=:." %I IN ('chcp') DO (SET _codepage1_=%I && SET _codepage_=Cp%_codepage1_% && ECHO %_codepage_%)