bash / awk中的“被零除”错误（可能是语法）

Question

I have a .tsv file that's continuously updated (ie every 5 minutes) with data. I'm trying to write a shell script which, when executed, identifies the rows in the .tsv file it hasn't seen yet, manipulates each row, and appends the new rows to a different file.

I've only done a very little shell scripting before, and this is my first time using awk , which is doing most of the actual processing of data.

When I try to run my script, I get this error: line 21: 0 /var/www/processed-temp-data: division by 0 (error token is "/www/processed-temp-data")

Line 21 is where I invoke awk :

awk -v awkLINES=$((LINES+1)) -v q="'" 'function CtoF(tempC)
{
        1.8 * tempC + 32
}

function make-dTime(tsvTime)
{
    split(tsvTime, dTime, /:_-/, seps)
    jsMonth = dTime[2] - 1
    dTime[1] ", " jsMonth ", " dTime[3] ", " dTime[4] ", " dTime[5] ", " dTime[6]
}

# skips past the lines already in output file
NR <= awkLINES { next }

# formats data
{ print "{c:[{v: new Date(" make-dTime($1) ")}, {v: q" CtoF($2)  $2 "q}, {v: q" $3 "q}]},"
}' /home/pi/dht-temp-log.tsv >>/var/www/processed-temp-data

Since I don't want to be doing any division at all, clearly something's going wrong. I expect I've made some sort of mistake with quoting or escape sequences or something, but I've been having a terrible time trying to pin down exactly what. Help would be greatly appreciated.

ETA

A line of input would look like:

2014-12-22_14:35:08     27.5     14.1  

That should be converted to

{c:[{v: new Date(2014, 11, 22, 14, 25, 08)}, {v: '81.5'}, {v: '27.5'}, {v: '14.1'}]},

Answer 1

The line 21 as pointed out by you invokes awk command. awk -v takes a variable as an argument and assigns the value to the variable, before execution of the program begins. See the awk man page . What is possibly happening here is your variable awkLINES gets a value like 0 /var/www/processed-temp-data which the system is trying to evaluate. The expression clearly shows that 0 is being divided by the following expression. Hence, a “Division by Zero” error.

Answer 2

This awk script should work:

awk -v awkLINES=0 -v q="'" 'function CtoF(tempC) {
   return 1.8 * tempC + 32
}

function make_dTime(tsvTime) {
   split(tsvTime, dTime, /[:_-]/)
   jsMonth = dTime[2] - 1
   return dTime[1] ", " jsMonth ", " dTime[3] ", " dTime[4] ", " dTime[5] ", " dTime[6]
}

# skips past the lines already in output file
# formats data
NR > awkLINES {
   print "{c:[{v: new Date(" make_dTime($1) ")}, {v: "q CtoF($2) q "}, {v: " q $2 q "}, {v: "q $3 q "}]},"
}' /home/pi/dht-temp-log.tsv

OUTPUT:

{c:[{v: new Date(2014, 11, 22, 14, 35, 08)}, {v: '81.5'}, {v: '27.5'}, {v: '14.1'}]},