使用LWP :: UserAgent提交HTTP POST请求，并将XML文件内容作为正文

Question

#!/usr/bin/perl -w

use strict;

use FileHandle;
use LWP::UserAgent;
use HTTP::Request;

sub printFile($) {

  my $fileHandle = $_[0];

  while (<$fileHandle>) {
    my $line = $_;
    chomp($line);
    print "$line\n";
  }
}

my $message = new FileHandle;

open $message, '<', 'Request.xml' or die "Could not open file\n";
printFile($message);

my $url = qq{https://host:8444};

my $ua = new LWP::UserAgent(ssl_opts => { verify_hostname => 0 });

$ua->proxy('http', 'proxy:8080');
$ua->no_proxy('localhost');

my $req = new HTTP::Request(POST => $url);
$req->header('Host' => "host:8444");
$req->content_type("application/xml; charset=utf-8");
$req->content($message);
$req->authorization_basic('TransportUser', 'TransportUser');

my $response = $ua->request($req);
my $content  = $response->decoded_content();
print $content;

I am getting the following error.

I want to submit post request using LWP::UserAgent and I want to give the location of an XML file as the body. I am getting invalid request body error. Request Body is invalid

Answer 1

I don't understand what printFile is for, but you are passing file handle $message as the message body, not the contents of the file.

Please take note of the following

• Always use warnings instead of the -w comment line option

• Never use subroutine prototypes. sub printFile($) should be just sub printFile

• There is no need to use FileHandle to work with files

• The reason for a file open failure is in $! . You should always include it in the die string

• Never use the indirect object notation. new LWP::UserAgent should be LWP::UserAgent->new

This version of your code may work a little better, but I have no way of testing it

#!/usr/bin/perl

use strict;
use warnings;

use LWP;

my $message = do {
  open my $fh, '<', 'Request.xml' or die "Could not open file: $!";
  local $/;
  <$fh>;
};

my $url = 'https://host:8444';

my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });

$ua->proxy(qw/ http proxy:8080 /);
$ua->no_proxy('localhost');

my $req = HTTP::Request->new(POST => $url);
$req->header(Host => 'host:8444');
$req->content_type('application/xml; charset=utf-8');
$req->content($message);
$req->authorization_basic('TransportUser', 'TransportUser');

my $response = $ua->request($req);
my $content  = $response->decoded_content;
print $content;