XSLT父内容在子节点之间拆分

Question

XML:

<text> Day light saving normally starts on 
<date>29 March 2015 </date> 
in some countries     
<footnote> <text> According to wikipedia </text> </footnote> 
in Europe </text>

Expected Output:

Day light saving normally starts on 29 March 2015 in some
countries<sup>1</sup> in Europe

<sup>1</sup> According to wikipedia

What could be the XSLT?

In my XSLT, I am trying to use node() to capture all the elements and contents, but in vain.

<xsl:template match="text">
<xsl:if test= "./footnote">
   <xsl:for-each select="node()">
     <xsl:if test= "not(name() = footnote">
           <xsl:value-of select="text()" />
     </xsl:if>
     <xsl:if test= "name() = footnote">
       <xsl:apply-templates select="text()" mode="footnote"/>
     </xsl:if>
    </xsl:for-each>
</xsl:if>

<xsl:template match="text/footnote" mode="footnote">
<xsl:element name="FootNote">
  <xsl:value-of select="." />
</xsl:element>
</xsl:template>

Answer 1

You can do this with <xsl:number> :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/">
    <div>
      <div>
        <xsl:apply-templates />
      </div>
      <xsl:apply-templates select="//footnote" mode="footnotes" />
    </div>
  </xsl:template>

  <xsl:template match="footnote" name="Index">
    <sup>
      <xsl:number level="multiple" />
    </sup>
  </xsl:template>

  <xsl:template match="footnote" mode="footnotes">
    <div>
      <xsl:call-template name="Index" />
      <xsl:text> </xsl:text>
      <xsl:apply-templates select=".//text()" />
    </div>
  </xsl:template>

</xsl:stylesheet>

When run on this input:

<text>
  Day light saving normally starts on
  <date>29 March 2015 </date>
    <footnote>
    <text> A very marvelous date </text>
  </footnote>

  in some countries
  <footnote>
    <text> According to wikipedia </text>
  </footnote>
  in Europe
</text>

The result is:

<div>
  <div>
  Day light saving normally starts on
  29 March 2015 <sup>1</sup>

  in some countries
  <sup>2</sup>
  in Europe
</div>
  <div><sup>1</sup>  A very marvelous date </div>
  <div><sup>2</sup>  According to wikipedia </div>
</div>