使用命令行查找和替换（组织）？

Question

I have a huge txt file that's organized like this:

Test User</b></a>&nbsp;</td>
user@hotmail.com</a></td>
04-17-2012</span></td>
02-13-2013</span></td>
Another Test</b></a>&nbsp;</td>
fake@spam4.me</a></td>
11-06-2011</span></td>
11-09-2012</span></td>
Username123</b></a>&nbsp;</td>
email@test.com</a></td>
06-07-2011</span></td>
06-03-2013</span></td>
AdminTest</b></a>&nbsp;</td>
testing@gmail.com</a></td>
05-01-2012</span></td>
06-05-2014</span></td>

Here's how I want the list to actually look:

Test User,user@hotmail.com,04-17-2012,02-13-2013
Another Test,fake@spam4.me,11-06-2011,11-09-2012
Username123,email@test.com,06-07-2011,06-03-2013
AdminTest,testing@gmail.com,05-01-2012,06-05-2014

Is there any simple way to do this through command line or should I be trying to go a different route?

Answer 1

Using awk you can do:

awk -v OFS=, '{sub(/<.*$/, "")} NR%4==1{a=$1} NR%4==2{b=$1} NR%4==3{c=$1}
    NR%4==0{print a, b, c, $1}' file
Test,user@hotmail.com,04-17-2012,02-13-2013
Another,fake@spam4.me,11-06-2011,11-09-2012
Username123,email@test.com,06-07-2011,06-03-2013
AdminTest,testing@gmail.com,05-01-2012,06-05-2014

• sub command strips all HTML tags after data
• Using modulo math it grabs 4 values from 4 consecutive rows
• When NR%4==0 it prints all the values.

Answer 2

Step 1 is to remove the XML-ish end-tag junk. That might be:

sed 's/<.*//'

Step 2 is to collect related lines into one. For that, I'd use awk . One issue is how many lines constitute an entry. Are there always just two dates, or could there be a variable number? Is a new entry always started with a capital letter, or should we just assume any letters? Does a user name ever start with a digit?

Assuming that a line with a leading capital letter starts a new entry, then this accumulates an arbitrary number of email address lines and date lines after a user name line:

awk '/^[A-Z]/ { if (line != "") print line; line = $0; next }
              { line = line "," $0 }
     END      { if (line != "") print line }'

It's a bit messy though to run two commands, so we can get awk to clean up its input with:

awk '         { sub(/<.*/, "") }
     /^[A-Z]/ { if (line != "") print line; line = $0; next }
              { line = line "," $0 }
     END      { if (line != "") print line }'

If the criteria for separating blocks of input lines are different (the key is not the leading capital letter), then the code can be changed accordingly.