如何批量保存进度

Question

I am making an interactive fiction game using windows batch script. I sorta figured out how to do it, but I can't for the life of me figure out why it wont work.

This is the loader:

@echo off
cls
:load
set /p s_name=Name:
if not exist "savedata/%s_name%/" goto user_error
set /p %name%= <savedata/%s_name%/name.pok
set /p %money%= < savedata/%s_name%/money.pok
set /p %area%= < savedata/%s_name%/location.pok
echo Name: %name%
echo Money: %money%
echo Location: Area %area%
echo.
pause
exit
:user_error
cls
echo.
echo File Not Found.
echo.
echo.
pause
exit

and this is the save file creator:

@echo off
cls
set /p lnm=Your Name:
set m=700
set l=27
md "savedata/%lnm%"
echo %lnm% > savedata/%lnm%/name.pok
echo %m% > savedata/%lnm%/money.pok
echo %l% > savedata/%lnm%/location.pok
echo save complete.
pause

Mind you, these are just tests, but you get the point.

Answer 1

Necessary changes:

• check again set /p %name%= (and so on) command;
• note no surrounding nor leading nor trailing spaces with > and < redirectors (as well as with = assignments in set commands).

The loader:

set /p name=<savedata/%s_name%/name.pok
set /p money=<savedata/%s_name%/money.pok
set /p area=<savedata/%s_name%/location.pok
echo Name: %name%, echo Money: %money%, echo Location: Area %area%

The save file creator:

md "savedata/%lnm%" 2>nul
echo %lnm%>savedata/%lnm%/name.pok
echo %m%>savedata/%lnm%/money.pok
echo %l%>savedata/%lnm%/location.pok
echo save complete.
echo Name: %lnm%, echo Money: %m%, echo Location: Area %l%

Output (without some echo s and cls s):

==>29036918load
Name:nn
File Not Found.
Press any key to continue . . .

==>29036918save
Your Name:nn
save complete.
Name: nn, echo Money: 700, echo Location: Area 27
Press any key to continue . . .

==>29036918load
Name:nn
Name: nn, echo Money: 700, echo Location: Area 27
Press any key to continue . . .

==>

Answer 2

What I would recommend would be to reserve one character or string as a prefix for the variables you want to save/reload. This way, your save routine and reload routine are vastly simplified.

For instance, choose $ as a prefix reserved for save/reload variables, then

set $>filename

is your save routine (every variable starting $ will be saved in filename as individual lines in varname=value format) for instance

$money=700

And your reload routine is simply

for /f "delims=" %%a in (filename) do set "%%a"

which then reloads the variables from the file.

This way, you don't need to change anything when you want to save another variable - so long as the variablename starts $ , it will be saved when the save line is executed and reloaded by the reload line described.

Meanwhile, please note that / introduces switches in cmd and \\ is the directory-separator. "quote strings that may contain spaces" if they are used as filenames - so "%filename%" will access the file Fred Bloggs if the variable filename contains the value Fred Bloggs

---

Here's an example:

@ECHO OFF
SETLOCAL

:: initial setup

SET $money=700
SET $location=27
SET $lnm=Fred Bloggs

:: (naturally, you could input LNM with a set/p if you wanted to)

:: Save the values in a file

SET $>"U:\%lnm%.pok"

:: Display values - I

echo Name: %$lnm%
echo Money: %$money%
echo Location: Area %$location%

:: Display values - II (for debugging while programming)

SET $

ECHO ============================================

ECHO Now CHANGE values

SET $money=50
SET $location=99

:: Display values - II (for debugging while programming)

SET $

ECHO ============================================

ECHO Now RELOAD values

for /f "usebackqdelims=" %%a in ("U:\%lnm%.pok") do set "%%a"

:: Display values - II (for debugging while programming)

SET $

GOTO :eof

Note that I'm creating a file containing all of the $ variables (on my U: drive for convenience)

The usebackq option is required because the filename is quoted.

Note how the original values are restored from the file. If you type the file, it will show lines in an obvious manner.

The key to this method is to use a prefix ( $ ) to the variables-of-interest.

Answer 3

I have created a game similar to this and figured I would share my solution. What I did was I had my game as a batch command and I had each player in a seperate folder named "players", to save the progress I would write the batch command to call when starting back up. For example, if I only had the location variable, and money, whenever I would want to have the script save the game such as visiting a town or whatever you want, I would call a function like this each time I wanted to save:

call :SAVE_GAME_DATA

:SAVE_GAME_DATA
echo(
    set location=%location%
    set money=%money%
)>.\Players\%name%.bat

then every time you would run the script it would ask for your name and load up the batch file it wrote for your name. Like so:

:startup
echo Welcome to whatever game it is!
echo.
set /p name=Please enter your name:
call .\Players\%name%.bat

::rest of your code goes here

Of course, you would have to have logic of that if .\\Players\\%name%.bat does not exist then it would run the user through a character creation process and save default variables such as default location and set money=0 for example, then call the save_game_data subroutine to save the default values for the new character.